Fill column with "X" based of on value of another cell

[p9j123]

Need help on creating a macro for this scenario, I hope this to automatically run as I change value.

If I enter 5 on C2 the macro should put "X" on D2:H2
If I enter 3 on H3 the macro should put "X" on I3:K3


This i currently what I have but it is hanging for some reason.

Private Sub Worksheet_Change(ByVal Target As Range)
x = ActiveCell.Value
For i = 1 To x
ActiveCell.Offset(-1, i).Value = i
Next i


End Sub

 

[Fluff]

How about

Private Sub Worksheet_Change(ByVal Target As Range)
   If Target.CountLarge > 1 Then Exit Sub
   Application.EnableEvents = False
   Target.Offset(, 1).Resize(, Target.Value).Value = "X"
   Application.EnableEvents = True
End Sub

 

[p9j123]

Thank @Fluff, can we modify so that it runs only if the value is numeric? and only on the specific area let say from Column F to Column Z only/

 

[Fluff]

Are columns F:Z the columns with the numeric value?

 

[p9j123]

Columns F:Z may or may not have a numeric value, I hope we can modify to run only and only if the value entered on F:Z are numeric if not it will just ignore the macro and will not do anything.

 

[Fluff]

How about

Private Sub Worksheet_Change(ByVal Target As Range)
   If Target.CountLarge > 1 Then Exit Sub
   If Not Intersect(Target, Range("F:Z")) Is Nothing Then
      Application.EnableEvents = False
      If IsNumeric(Target) Then Target.Offset(, 1).Resize(, Target.Value).Value = "X"
      Application.EnableEvents = True
   End If
End Sub

 

[p9j123]

Just what I needed @Fluff, one problem though when I delete a content I am having an error that says "Application-defined or object-defined error"

 

[Fluff]

Swap that line for

      If Application.IsNumber(Target) Then Target.Offset(, 1).Resize(, Target.Value).Value = "X"

You may also need to run

Sub chk()
Application.EnableEvents = True
End Sub

 

[p9j123]

Thank you so much for your help

 

[Fluff]

You're welcome & thanks for the feedback