Extracting differences between two comma-separated strings

[NewOrderFac33]

Good afternoon - I have two columns of comma-separated two character codes (for example):

A                                                           B
AA,DB,LN,WE,UR,TD,QW                         AA,LN,WE,VF,WE,UR,OW,ZL

The the codes will always comprise two characters, but will not necessarily be in alphabetical order.

In the next column, I need to create a comma-separated string comprising all the two digit codes from the first list that do NOT appear in the second.

So, in the above example, the third column will contain DB,TD

Do any of you fine folk have any suggestions of the best way in which I can accomplish this?

Thanks in advance

Pete

 

[MickG]

Try this, seems to work !!

Function nStr(R1 As String, R2 As String) As String
Dim Sp As Variant, n As Long
Sp = Split(R1, ",")
For n = 0 To UBound(Sp)
    If InStr(R2, Sp(n)) > 0 Then
        nStr = nStr & IIf(nStr = "", Sp(n), "," & Sp(n))
    End If
Next n
End Function

Regards Mick

 

[NewOrderFac33]

Just to show I'm not being lazy, I came up with this:

Function WhatsCommon(a As String, b As String) As String
    Dim i As Long
    Dim MyString As String
    Dim MySplit As Variant
    
    MySplit = Split(b, ",")
    
    For i = 0 To UBound(MySplit)
        If InStr(a, MySplit(i)) > 0 Then
            MyString = MyString & IIf(MyString = "", MySplit(i), "," & MySplit(i))
        End If
    Next i
    WhatsCommon = MyString
End Function

P.S - I didn't copy, Mick, honestly! - Thank you, too!

 

[MickG]

Excellent:-
Their almost a matching pair !!!!

 

[NewOrderFac33]

Here's my reworking of Fluff's original function to identify uniques, using the same nomenclature, too:

Function WhatsUnique(a As String, b As String) As String
   Dim i As Long
   Dim Asplit As Variant
   Dim Bsplit As Variant
   
   Asplit = Split(a, ",")
   Bsplit = Split(b, ",")
   
   For i = 0 To UBound(Bsplit)
      Asplit = Filter(Asplit, Bsplit(i), False, vbTextCompare)
   Next i
   WhatsUnique = Join(Asplit, ",")
End Function

To all who helped, thank you and have a great weekend!

Pete

 

[MickG]

You're very welcome

Regards Mick