Excel saving a file witout quotations

[5h1v]

Hey,

I am trying to make some VBA that saves one row of data from a spreadsheet and saves it as a PRN file which I can do but it adds quotation marks to the start and end of every row, how do I go about removing them without having to do it manually?

Here is my code;

   Sheets("Olink").Select
    Columns("P:P").Select
    Range("P188").Activate
    Selection.Copy
    Sheets.Add after:=ActiveSheet
    Worksheets.Add().Name = "DD"
    Range("A1").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    myFolder = Application.GetSaveAsFilename(fileFilter:="PRN (*.prn), *.prn")
    ActiveWorkbook.SaveAs Filename:=myFolder, FileFormat:=xlCSV, CreateBackup:=False
End Sub

 

[Joe4]

Using the techniques shown here: https://analysistabs.com/vba/vba-write-string-text-file-without-quotes/

The code would look something like this:

Sub ExportData()

    Dim lr As Long
    Dim r As Long
    Dim myFileName As String
    Dim cellValue As Variant
    
    Sheets("Olink").Select
    
'   Find last row with data in column P
    lr = Cells(Rows.Count, "P").End(xlUp).Row
    
'   Prompt for full file path and name
    myFileName = Application.GetSaveAsFilename(fileFilter:="PRN (*.prn), *.prn")
    
'   Create new file
    Open myFileName For Output As [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=1]#1[/URL] 
    
'       Loop through all rows in column P
        For r = 1 To lr
'           Capture value of cell
            cellValue = Cells(r, "P").Value
'           Write to text file
            Print [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=1]#1[/URL] , cellValue
'       Move to next row
        Next r
'   Close text file
    Close [URL=https://www.mrexcel.com/forum/usertag.php?do=list&action=hash&hash=1]#1[/URL] 

    MsgBox myFileName & " created"

End Sub

Note that there isn't any need to copy the data to a new sheet to do this. We can do it from column P on the Olink sheet.

 

[5h1v]

Just tried this and it works perfectly, thank you so much this will save me so much time removing the excess characters.

 

[Joe4]

You are welcome.
Glad I was able to help!