Excel-Move Rows to another sheet based on Cell Value

[Robertson1995]

Hello. I am needing help with code that will move specific rows to another sheet in the same workbook based on a Cell Value. In my workbook, I have a sheet named "Notes" that has values in Columns A-C. I need a code that when I enter the letter "X" in column D, it will copy the contents of A-C for that row and paste a copy on the first empty row in a sheet named "Note History". The copy will need to be the first empty row in Columns A-C for the Note History sheet. I also need the code to delete the entire row from the "Notes" sheet once it has copied the contents to the "Note History" sheet. Thank you in advance for any help.

 

[Sharid]

take a look at this, Click here

 

[JLGWhiz]

You can only have one of a type of event code per sheet code module. So if you have the old code in sheet 'Notes' then you will need to either delete the old code and install the new one, or combine the two into one.

Private Sub Worksheet_Change(ByVal Target As Range)
Application.EnableEvents = False
If Not Intersect(Target, Range("G:G")) Is Nothing Then
    If UCase(Target.Value) = "CLOSED" Then
        Target.EntireRow.Cut Sheets("Close").Cells(Rows.Count, 1).End(xlUp)(2)
    End If
End If
Application.EnableEvents = True
End Sub

 

[JLGWhiz]

This would be the combined event code for sheet "Notes" code module.

rivate Sub Worksheet_Change(ByVal Target As Range)
    If Target.Cells.Count > 1 Then Exit Sub
    Application.EnableEvents = False
        If Not Intersect(Target, Columns(4)) Is Nothing Then
            If UCase(Target.Value) = "X" Then
                Range("A" & Target.Row).Resize(1, 3).Copy Sheets("Note History").Cells(Rows.Count, 1).End(xlUp)(2)
                Target.EntireRow.Delete
            End If
        ElseIf Not Intersect(Target, Range("G:G")) Is Nothing Then
            If UCase(Target.Value) = "CLOSED" Then
                Target.EntireRow.Cut Sheets("Close").Cells(Rows.Count, 1).End(xlUp)(2)
            End If
        End If
    Application.EnableEvents = True
End Sub