Cycle Count Generator

[kumatsu]

I am wanting to create a random pick generator that picks 15-20 numbers from a list without repeating and keeping track of the picked numbers and not picking them again in future picks. But will auto reset once all the items in the list have been picked. If possible.

 

[DanteAmor]

Hi @kumatsu , check if the following macro meets what you require.
The first time, it selects 15 items at random, the next time it selects 15 items at random without repeating the previous ones, and so on. (I hope to meet @Joe4 's expectations ).

The first 15 records will be in cell I3 through I17, the next I18 through I32, and so on.

If you want to change the random number, change the 15 in this line:
num = 15 'random numbers

Try:

Sub Select_Random_Names()
  Dim dic As Object
  Dim a As Variant, b As Variant, c As Variant, d As Variant
  Dim i As Long, j As Long, k As Long, lr2 As Long, x As Long, y As Long
  Dim arr As Variant, num As Long
  
  num = 15      'random numbers
  
  Set dic = CreateObject("Scripting.Dictionary")
  a = Range("A2", Range("A" & Rows.Count).End(3)).Value
  lr2 = Range("I" & Rows.Count).End(3).Row
  If lr2 > 3 Then
    b = Range("I3:I" & lr2).Value
    If UBound(a, 1) = UBound(b, 1) Then
      MsgBox "All items have been selected. It will start again."
      Range("I3:I" & lr2).Cells.ClearContents
      lr2 = 2
    Else
      For i = 1 To UBound(b, 1)
        dic(b(i, 1)) = Empty
      Next
    End If
  End If
  ReDim c(1 To UBound(a, 1), 1 To 1)
  ReDim d(1 To num, 1 To 1)
  
  For i = 1 To UBound(a, 1)
    If Not dic.exists(a(i, 1)) Then
      j = j + 1
      c(j, 1) = a(i, 1)
    End If
  Next
  
  arr = Evaluate("ROW(1:" & j & ")")
  Randomize
  num = WorksheetFunction.Min(num, UBound(arr))
  
  For i = 1 To num
    x = Int(Rnd * j + i)
    y = arr(i, 1)
    arr(i, 1) = arr(x, 1)
    arr(x, 1) = y
    
    k = k + 1
    d(k, 1) = c(arr(i, 1), 1)
    j = j - 1
  Next i
  
  Range("I" & lr2 + 1).Resize(num).Value = d
End Sub

 

[Joe4]

Dante, thanks for weighing in and helping out!
I came across some other posts on this forum where you were able to do similiar things (and pretty cool things!).
Sadly, I am not very proficient the Scripting Dictionary, and haven't done too much advanced work with arrays.

 

[kumatsu]

Hi @kumatsu , check if the following macro meets what you require.
The first time, it selects 15 items at random, the next time it selects 15 items at random without repeating the previous ones, and so on. (I hope to meet @Joe4 's expectations ).

The first 15 records will be in cell I3 through I17, the next I18 through I32, and so on.

If you want to change the random number, change the 15 in this line:
num = 15 'random numbers

Try:

Sub Select_Random_Names()
  Dim dic As Object
  Dim a As Variant, b As Variant, c As Variant, d As Variant
  Dim i As Long, j As Long, k As Long, lr2 As Long, x As Long, y As Long
  Dim arr As Variant, num As Long
 
  num = 15      'random numbers
 
  Set dic = CreateObject("Scripting.Dictionary")
  a = Range("A2", Range("A" & Rows.Count).End(3)).Value
  lr2 = Range("I" & Rows.Count).End(3).Row
  If lr2 > 3 Then
    b = Range("I3:I" & lr2).Value
    If UBound(a, 1) = UBound(b, 1) Then
      MsgBox "All items have been selected. It will start again."
      Range("I3:I" & lr2).Cells.ClearContents
      lr2 = 2
    Else
      For i = 1 To UBound(b, 1)
        dic(b(i, 1)) = Empty
      Next
    End If
  End If
  ReDim c(1 To UBound(a, 1), 1 To 1)
  ReDim d(1 To num, 1 To 1)
 
  For i = 1 To UBound(a, 1)
    If Not dic.exists(a(i, 1)) Then
      j = j + 1
      c(j, 1) = a(i, 1)
    End If
  Next
 
  arr = Evaluate("ROW(1:" & j & ")")
  Randomize
  num = WorksheetFunction.Min(num, UBound(arr))
 
  For i = 1 To num
    x = Int(Rnd * j + i)
    y = arr(i, 1)
    arr(i, 1) = arr(x, 1)
    arr(x, 1) = y
   
    k = k + 1
    d(k, 1) = c(arr(i, 1), 1)
    j = j - 1
  Next i
 
  Range("I" & lr2 + 1).Resize(num).Value = d
End Sub

Good morning,

When I go to run it, I'm getting the following error

 

[DanteAmor]

Did you copy the entire macro?
When you press "Ok", any line of the macro is highlighted in blue color?
Try my file:

random names v1.xlsm

drive.google.com

 

[kumatsu]

Did you copy the entire macro?
When you press "Ok", any line of the macro is highlighted in blue color?
Try my file:

random names v1.xlsm

drive.google.com

Thank you!! I got. You two have been a great help!!

 

[DanteAmor]

I'm glad to help you. Thanks for the feedback.

 

[Joe4]

Glad we were able to help!
And thanks for jumping on and saving the day, Dante!

 

[motion6420]

Thank you!! I got. You two have been a great help!!

can i get a copy of your file? i am trying to set up a cycle count program