Count unique values with condition

[rlobera]

Hi everyone, hope you can help me with this issue.

I have a sheet that looks like this

Subscriber_ID	Date
101	09/01/18
101
202	08/13/18
203	09/04/18
204
205	09/08/18
205

<tbody>
</tbody>

I need to count records from September in the "Date" column and only when it's not repeated in the "Subscriber_ID" column. In this case, the correct answer will be 1, because is the only one that matches the condition. As you may see, subscriber_ID 203 it the only record that it's not repeated and also that the date falls within September. Subscribers 101 and 205 should not be considered since both are repeated, in spite of having a date that matches.

 

[admiral100]

Hi,

Try this

Ctrl+Shift+Enter NOT just Enter

D2 =INDEX(A2:A8,MATCH(1,IF(MONTH(B2:B8)=9,IF(1/COUNTIF(A2:A8,A2:A8)=1,1)),0))

	A	B	C	D
1	Subscriber_ID	Date
2	101	01/09/18		203
3	101
4	202	13/08/18
5	203	04/09/18
6	204
7	205	08/09/18
8	205

<colgroup><col><col><col span="3"></colgroup><tbody>
</tbody>

 

[Aladin Akyurek]

Control+shift+enter, not just enter:

=SUM(IF(FREQUENCY(A2:A8,A2:A8)=1,IF(B2:B8-DAY(B2:B8)+1=D1,1)))

where D1 is 2018-09-01.

 

[rlobera]

-

 

[rlobera]

Control+shift+enter, not just enter:

=SUM(IF(FREQUENCY(A2:A8,A2:A8)=1,IF(B2:B8-DAY(B2:B8)+1=D1,1)))

where D1 is 2018-09-01.

Looks like it worked. Want to better understand the part of the formula where you're using the DAY function. I already know about arrays and the FREQUENCY function.

Also, what the formula would look like if I add a column with another field that also has to match?

 

[rlobera]

Hi,

Try this

Ctrl+Shift+Enter NOT just Enter

D2 =INDEX(A2:A8,MATCH(1,IF(MONTH(B2:B8)=9,IF(1/COUNTIF(A2:A8,A2:A8)=1,1)),0))

	A	B	C	D
1	Subscriber_ID	Date
2	101	01/09/18		203
3	101
4	202	13/08/18
5	203	04/09/18
6	204
7	205	08/09/18
8	205

<tbody>
</tbody>

Not exactly what I was looking for since I want to count records that meet the criteria, not a formula that returns the value that matches.

 

[admiral100]

To count try this

=COUNT(IF(MONTH(B2:B8)=9,IF(1/COUNTIF(A2:A8,A2:A8)=1,1)))

 

[rlobera]

To count try this

=COUNT(IF(MONTH(B2:B8)=9,IF(1/COUNTIF(A2:A8,A2:A8)=1,1)))

You did it, now it worked! Thank you!

As I already asked to Aladin Akyurek, what the formula would look like if I add a column with another field that also has to match a condition?

 

[Aladin Akyurek]

Looks like it worked. Want to better understand the part of the formula where you're using the DAY function. I already know about arrays and the FREQUENCY function.

Also, what the formula would look like if I add a column with another field that also has to match?

The FREQUENCY formula works faster and is more flexible.

Any given date can be turned into a first day date, using the DAY function:

=TODAY()-DAY(TODAY())+1

takes off the day part of today and adds 1 to the result. Thus:

10/6/2018 >> 10/0/2018 >> 10/1/2018

In the formula we have we are interested only in the October 2018 dates: That is, every October 2018 dates.


Anther condition: Example...

{=SUM(IF(FREQUENCY(A2:A8,A2:A8)=1,IF(B2:B8-DAY(B2:B8)+1=D1,IF(C2:C8="jon",1))))}

 

[rlobera]

The FREQUENCY formula works faster and is more flexible.

Any given date can be turned into a first day date, using the DAY function:

=TODAY()-DAY(TODAY())+1

takes off the day part of today and adds 1 to the result. Thus:

10/6/2018 >> 10/0/2018 >> 10/1/2018

In the formula we have we are interested only in the October 2018 dates: That is, every October 2018 dates.


Anther condition: Example...

{=SUM(IF(FREQUENCY(A2:A8,A2:A8)=1,IF(B2:B8-DAY(B2:B8)+1=D1,IF(C2:C8="jon",1))))}

It worked great, thanks a lot!