Contar filas mediante condiciones

[Timak]

Hola.

Supongamos la siguiente imagen

Va sobre el baloncesto. Cada fila representa las estadísticas de un partido de un jugador concreto (son 21 partidos de baloncesto)

Mi duda es el siguiente: quiero contar las filas en las que el jugador ha conseguido un doble-doble en puntos (columna O) y rebotes (columna I), es decir, que haya conseguido más de 10 pts y más de 10 reb en un mismo partido (una misma fila). Entonces en ese ejemplo serían 2 dobles-dobles.

No encontré ninguna función que me haga eso. He probado con CONTAR.SI, pero no salió el valor que quiero.

Agradecería mucho toda la ayuda

Saludos.

 

[Greg Truby]

OK – primeramente si usted no se dio cuenta, lo que estamos haciendo es convirtiendo expresiones Boolean (lógicas) a expresiones numéricas. O sea<?xml:namespace prefix = o ns = "urn:schemas-microsoft-comfficeffice" /><o></o>

• Cierto vale 1<o></o>
• Falso vale 0<o></o>

{Note que en mis ejemplos no uso los datos de usted sino imaginarios.}

Entonces la expresión (I2>9) se evalua a Cierto o Falso y (I1:I6>9) se evalua a una matrix como {CIERTO, FALSO, FALSO, FALSO, CIERTO,CIERTO}. <o></o>

Ahora hacemos lo mismo con (O1:O6>9) que se supone evalua a {FALSO,FALSO,CIERTO,FALSO,CIERTO,CIERTO}


Podemos convertir los valores Boolean por coaccionar usando «--» o sea:<o></o>

• --(I1:I6>9) brindaría {1,0,0,0,1,1} y<o></o>
• --(O1:O6>9) brindaría {0,0,1,0,1,1}<o></o>

Si hacemos operaciones de matrices dentro de Sumproduct la función convierte las matrices a valores numéricos al realizar la operación de sumar o multiplicar. Si multiplicamos las dos matrices arriba, resulta una matriz {0,0,0,0,1,1} y luego Sumproduct suma tal matriz para llegar a la suma de 2.<o></o>

En matemática “Boolean”, multiplicar es el “AND” y sumar es el “OR” (restar uno es “NOT”).
<o></o>

Su primera pregunta fue rebotes Y puntos entonces hicimos:<o></o>
(I1:I21>9)*(O1:O21>9)<o></o>

Ahora pregunta sobre apoyos (assists) Y puntos, entonces multiplicamos J por O:
(J1:J21>9)*(O1:O21>9)<o></o>

Y pregunta sobre apoyos Y rebotes, entonces multiplicamos I por J:<o></o>
(I1:I21>9)*(J1:J21>9)<o></o>

Pero usted quiere saber sobre<o></o>
[rebotes Y puntos] O [apoyos Y puntos] O [rebotes Y apoyos]



Entonces necesitamos sumar las tres expresiones:<o></o>

• (I2:I22>9)*(J2:J22>9) + (I2:I22>9)*(O2:O22>9) + (J2:J22>9)*(O2:O22>9)<o></o>

Entonces la fórmula que quiere es:<o></o>

• =SUMPRODUCT((I2:I22>9)*(J2:J22>9)+(I2:I22>9)*(O2:O22>9)+(J2:J22>9)*(O2:O22>9))<o></o>

Pero cabe una duda – ¿qué pasa si el jugador tiene 10 c/u de rebotes, apoyos y puntos (un «doble triple»)? ¿Se cuenta como uno o como tres? Si vale 3 la fórmula arriba sirve. Si vale uno se puede arreglar usando SIGN.<o></o>

• =SUMPRODUCT(SIGN((I2:I22>9)*(J2:J22>9)+(I2:I22>9)*(O2:O22>9)+(J2:J22>9)*(O2:O22>9)))<o></o>

<o></o>EDIT -- Disculpe, cuando estuve haciendo las pruebes inserté una fila de cabezas asi que le queda la tarea de ajustar la fórmula para que coincida a filas 1 a 21 en vez de 2 a 22. :wink:

 

[Timak]

Greg, muchísimas gracias por todo. Es la solución perfecta.

Ya no le molesto más, pues ya tengo todo lo que necesito

Un saludo y lo dicho, muchas gracias de nuevo.