Compile Error - VBA

[ADSkinner]

Hello All....

I have a VBA code that should be taking worksheets and saving them each as their own excel file in a new folder. I had previously had this code working, but then made some modifications to my file, and as a result, this code is now giving me a "Compile Error: Wrong number of arguments or invalid property assignment" on this line of code: DateString = Format(Now, "yyyy-mm-dd hh-mm-ss")

Here is the entire code as it is written today. Can anyone help me?

Sub SplitWorkbook()
'Updateby20140612
Dim FileExtStr As String
Dim FileFormatNum As Long
Dim xWs As Worksheet
Dim xWb As Workbook
Dim FolderName As String
Application.ScreenUpdating = False
Set xWb = Application.ThisWorkbook
DateString = Format(Now, "yyyy-mm-dd hh-mm-ss")
FolderName = xWb.Path & "\" & xWb.Name & " " & DateString
MkDir FolderName
For Each xWs In xWb.Worksheets
    xWs.Copy
    If Val(Application.Version) < 12 Then
        FileExtStr = ".xls": FileFormatNum = -4143
    Else
        Select Case xWb.FileFormat
            Case 51:
                FileExtStr = ".xlsx": FileFormatNum = 51
            Case 52:
                If Application.ActiveWorkbook.HasVBProject Then
                    FileExtStr = ".xlsm": FileFormatNum = 52
                Else
                    FileExtStr = ".xlsx": FileFormatNum = 51
                End If
            Case 56:
                FileExtStr = ".xls": FileFormatNum = 56
            Case Else:
                FileExtStr = ".xlsb": FileFormatNum = 50
        End Select
    End If
    xFile = FolderName & "\" & Application.ActiveWorkbook.Sheets(1).Name & FileExtStr
    Application.ActiveWorkbook.SaveAs xFile, FileFormat:=FileFormatNum
    Application.ActiveWorkbook.Close False
Next
MsgBox "You can find the files in " & FolderName
Application.ScreenUpdating = True
End Sub

 

[ADSkinner]

This was the error. I had created a separate module that was Sub Format, once I renamed it, the code above now works.

Thank you both very much!!!!!!

 

[Fluff]

Glad we could help & thanks for the feedback

 

[Joe4]

This was the error. I had created a separate module that was Sub Format, once I renamed it, the code above now works.

Glad it all got sorted.

A common rule of thumb is to never choose reserved words (i.e. name of built-in functions, properties, methods, etc) as the name of your variables, procedures, or user defined functions.
Doing so causes ambiguity, errors, and unexpected results (like you experienced).
If you are not sure if a word is "reserved" or not, just add a prefix like "My" to it.