code help

[Kevin0427]

The following code never gets to the ELSE and always displays the message box. I suspect that it is because when I print the variables lastrow is right justified and rowfound is left justified so they are not both numbers. But I am not sure and if so I don't know how to fix it.

'Get Row Number
    rowfound = InputBox("What is the row number of the project?", "Input Row Number")
    
    'If Input box is cancelled exit sub
    If rowfound = "" Then
    Exit Sub
    End If
    
    'Is row number valid?
    lastrow = Sheets("Tracking Log").Range("B:B")(Rows.Count, 1).End(xlUp).Row
    
    Debug.Print lastrow
    Debug.Print rowfound
    
    If rowfound < 15 Or rowfouund > lastrow Then
        MsgBox "Row Number not valid", vbCritical, "Invalid Row Number"
        Exit Sub
    
    Else

 

[xenou]

I was also thinking you need to take care with the data types since you are getting a string answer. So dealing that I would write:

Option Explicit

Sub foo()
Dim rsp As String
Dim rowfound As Long
    
    rsp = InputBox("What is the row number of the project?", "Input Row Number")
    
    If rsp = "" Then
        Exit Sub
    End If
    
    If Not IsNumeric(rsp) Then
        MsgBox "Row Number must be a numeric value", vbCritical, "Invalid Row Number"
        Exit Sub
    Else
        rowfound = CLng(rsp)
    End If
    
    If (rowfound < 15) Then
        MsgBox "Row Number must be greater than or equal to 15", vbCritical, "Invalid Row Number"
        Exit Sub
    End If
    
    If (rowfound > Sheets("Tracking Log").Range("B:B")(Rows.Count, 1).End(xlUp).Row) Then
        MsgBox "Row Number cannot be greater than the last available row in Tracking Log", vbCritical, "Invalid Row Number"
        Exit Sub
    End If
    
    MsgBox "Else Reached (all validations passed)"
 
 End Sub

 

[Fluff]

PERFECTO !!! Thanks. I was trying .value all over the place with no avail.

You're welcome & thanks for the feedback