Classic 2003 Menus

[CoreyDickinson]

Just upgraded from Excel 2003 to 2010 and hate the new ribbon menu format. Can anyone recommend a good FREE add-in that will allow me to use the classic menus from Excel 2003?

 

[xenou]

Just saw this link too:
http://www.mrexcel.com/tip144.shtml

I was browsing ribbon topics last week and saw at least three more sites that offer ribbon transformations to restore "2003 look and feel". Hey, that's what ribbons all about, isn't it?

My unsolicited two cents, though is:
it takes about two weeks to get used to the new ribbon, and then it's quite natural to use. If you properly customize the QAT, learn some keyboard shortcuts, and even add some custom shortcuts, and become familiar with right-click menus, you can minimize the ribbon and hardly have any need to use it except for the more unusual tasks (such as editing chart layouts or data connections). No muss no fuss. I see the ribbon only rarely, without having to do anything other than minimize it.

Ribbon tips:
http://datapigtechnologies.com/blog/index.php/excel-2010-customizable-ribbon/
http://www.htstechtips.com/2011/05/21/customize-quick-access-toolbar-ribbon-bar-office-2010/

 

[dk]

The code below creates old style menus and command bars in Add-In tab of Ribbon.
Once upon a time it was made just for fun

' ZVI:2010-07-27 Creating of old style menus & CommandBars in Add-Ins tab of Excel 2007 Ribbon
[

The code can be put in Add-In

I haven't worked out how it works yet but that is some very clever code

 

[xenou]

^^ agreed. Not sure how it works yet either ...

 

[Biz]

ZVI very nice mate.

Biz

 

[ZVI]

Hi Alex (xenou),
Yea, good using of the Ribbon & QAT is the matter of time.
But if someone likes one brand a beer then let’s gives him drink it again

Thanks, Dk
Excel 2007/2010 stores the old style menus (already populated), command bars and controls for VBA code back compatibility.
All it can go via code to Add-Ins tab of the Ribbon.
It's benefit that menus automatically appear in Excel localization language.
My code is just a toy relative to MrExcel's product in the link provided by Xenou.
For example I can’t find the way to add the working color controls to the old style toolbars.

Biz, thank you mate!

Jmumme,
Below is my preferred version of the full code which is in Module1 only:

' All code should be in Module1:
Option Explicit

' Creating of old style menus & CommandBars in Add-Ins tab of Excel 2007 Ribbon
Private Sub CreateOldStyleMenus()
  If Workbooks.Count = 0 Then Workbooks.Add
  If Val(Application.Version) < 12 Then Exit Sub
  OldStyleDelete "Menus 2003", "Standard 2003", "Format 2003"
  NewCommandBar "Menus 2003", Array(30002.1, 30003.1, 30004.1, 30005.1, 30006.1, 30007.1, 30011.1, 30009.1, 30022.1, 30177.1, 30010.1)
  NewCommandBar "Standard 2003", Array(2520.01, 23.01, 3.01, 9004.01, 3738.01, 2521.01, 109.01, 2.01, 7343.01, 21.01, 19.01, 108.01, 128.06, 129.06, 9071.01, 1576.01, 226.13, 210.01, 211.01, 436.01, 1733.04, 30253.1, 984.01)
  NewCommandBar "Format 2003", Array(1728.04, 1731.04, 113.01, 114.01, 115.01, 120.01, 122.01, 121.01, 402.01, 1643.01, 396.01, 397.01, 398.01, 399.01, 3162.01, 3161.01)
End Sub

' Delete old style menus & CommandBars
Private Sub OldStyleDelete(ParamArray cbNames())
  Dim x: On Error Resume Next
  For Each x In cbNames
    CommandBars(x).Delete
  Next
End Sub

' Create old style menus & CommandBars
Private Sub NewCommandBar(cbName, cbIDs)
  Dim tp&, x: On Error Resume Next
  With CommandBars.Add(cbName, , , True).Controls
    .Parent.Visible = True
    For Each x In cbIDs
      tp = (x - Fix(x)) * 100
      .Add Type:=tp, ID:=x
    Next
  End With
End Sub

' Code automaticalu runs at loading
Private Sub Auto_Open()
  Application.OnTime Now, "CreateOldStyleMenus"
End Sub

' Code automaticalu runs at closing
Private Sub Auto_Close()
  OldStyleDelete "Menus 2003", "Standard 2003", "Format 2003"
End Sub

You can download already prepared Add-In with that code from the link: Excel2003menus.xla

Regards,
Vlad

 

[jmumme]

Awesome!!! Amazing!!
How that works, I have no idea.
Thank you so much..