Choose cells that come closest to adding up to a certain total

[melodramatic]

This is probably the strangest query I've put before you, and I think it's probably a dud. But, I'm hoping that someone can prove me wrong.

I am in charge of our daily lunch here at work, and break that lunch down on my credit card according to how many people from our two buildings (A&D) were on the lunch list. Accordingly, I charge out per the average meal cost against the number per building.

All has worked well since I took on this task a year ago. UNTIL, I.T. let some wonder-consultant change out all of our accounting software. I am no longer able to go into each charge and split it to different accounts - every single charge can go to only one charge code now. So much for splitting.

Luckily, I do my charge-outs only once a month (and that day is coming up on Wednesday, when May ends). What I'm planning on doing is taking the total of the charges for the month (using the April figures here, that was $1,425.10 for Bldg A, and $2,710.06 for Bldg D), and pulling receipts that match closest to that amount. Yes, the shortcut system that we now have in accounting takes us all 4x the amount of time to do accounting work.

Sorry, I digress in my frustration.

So, is there a way that I can tell Excel - "hey - if you look at the "A Charge" column in the table, (starting at Row 3, you're in a table), find me the receipts that will bring me the closest to $1,425.10?

Thanks in advance for looking at this!

$4,135.16	$1,425.10	$2,710.06
04-22	A	D
Date	Vendor	Type Meal	# Meals	A #	D #	Charge	A Charge	D Charge
04/04/22 (Mon)	Zaxbys	Chicken	21	7	14	$200.88	$66.96​	$133.92​
04/06/22 (Wed)	Romeros Las Brazas	Mexican	18	6	12	$275.84	$91.95​	$183.89​
04/07/22 (Thu)	First Class BBQ	BBQ	21	6	15	$255.60	$73.03​	$182.57​
04/08/22 (Fri)	Every Bellies	Potatoes & Burgers	19	7	12	$267.11	$98.41​	$168.70​
04/11/22 (Mon)	Chick-fil-A	Chicken Sandwiches, Wraps & Salads	16	5	11	$187.06	$58.46​	$128.60​
04/12/22 (Tue)	Schlotzskys	Sandwiches	19	7	12	$250.04	$92.12​	$157.92​
04/13/22 (Wed)	Joes Italian Grill	Italian	23	9	14	$319.09	$124.86​	$194.23​
04/14/22 (Thu)	French Quarter	Cajun	20	7	13	$325.41	$113.89​	$211.52​
04/18/22 (Mon)	Backyard Grill	American (w/seafood)	16	3	13	$224.46	$42.09​	$182.37​
04/19/22 (Tue)	McAlisters Deli	Sandwiches	19	6	13	$226.50	$71.53​	$154.97​
04/20/22 (Wed)	Yangs Kitchen	Chinese	27	11	16	$281.71	$114.77​	$166.94​
04/21/22 (Thu)	Classic Events Cafe	Burgers, etc.	20	6	14	$256.29	$76.89​	$179.40​
04/22/22 (Fri)	Smashburger	Burgers, etc.	17	6	11	$222.94	$78.68​	$144.26​
04/25/22 (Mon)	Zaxbys	Chicken	26	14	12	$260.39	$140.21​	$120.18​
04/26/22 (Tue)	Jersey Mikes	Sandwiches	21	4	17		$0.00​	$0.00​
04/27/22 (Wed)	Romeros Las Brazas	Mexican	24	8	16	$353.41	$117.80​	$235.61​
04/28/22 (Thu)	First Class BBQ	BBQ	18	5	13	$228.43	$63.45​	$164.98​
04/29/22 (Fri)	Every Bellies	Potatoes & Burgers	20	6	14		$0.00​	$0.00​

 

[KRice]

Hi @Xlambda, I would be very interested in seeing any alternative approaches. I've encountered several problems of this type--involving sums of partitions--with variations regarding the optimization objective: sometimes to minimize the difference between the target sum and the partition sum, other times to obtain the target sum with the fewest elements in the partition. I'll check out ARRANGEMENTS, and if you don't mine--just in case I miss a development there--if you develop something that might offer an alternative solution for @melodramatic to consider, would you mind posting back here with a link to the specific ARRANGEMENTS post? I appreciate your interest in this and thanks for looking into it further.

 

[Xlambda]

I appreciate your interest in this and thanks for looking into it further.

Yes Sir, Thank you Sir! I will prepare the presentation and I will place a link here also.

 

[Xlambda]

I appreciate your interest in this and thanks for looking into it further.

Hi again,
Here is the link: ARRANGEMENTS posts #34 - #38

 

[melodramatic]

Xlambda - I apologize for the long delay in answering - but D365 has been killing me, and I've not had time to look at anything.

I absolutely invite you to post under your thread, and will definitely go to look at it. However, I think this has hit the point that I've given up on the macro idea. Instead, what I've done is created a toggle, where I have a column where the actual charges are added, and then another column where charges add up according to whether I toggle the charge to go to A or D. At the top, a box tells me how close I am to the actual charge, and I just play with the numbers. For my July charges, I had about 90 charges, and actually was able to toggle the charges until I got them to $3.69 of the actual.

Meanwhile, thank you to everyone who tried to help me through this!

 

[Xlambda]

Xlambda - I apologize for the long delay in answering - but D365 has been killing me, and I've not had time to look at anything.

I absolutely invite you to post under your thread, and will definitely go to look at it. However, I think this has hit the point that I've given up on the macro idea. Instead, what I've done is created a toggle, where I have a column where the actual charges are added, and then another column where charges add up according to whether I toggle the charge to go to A or D. At the top, a box tells me how close I am to the actual charge, and I just play with the numbers. For my July charges, I had about 90 charges, and actually was able to toggle the charges until I got them to $3.69 of the actual.

Meanwhile, thank you to everyone who tried to help me through this!

No problem at all, take all the time you need. If you can provide more data I will consider finding other ways of approaching a solution, not only with ARRANGEMENTS posts #34 - #38

 

[KRice]

@melodramatic, I'm curious if you've tried the macro I posted previously. There were several variants, so to eliminate any potential confusion, I'll repost what I believe might be the easiest to implement. I've added a backend analysis utility to this version so that the most preferred combination (of those returned by the code) is automatically identified and used to produce the final results.

In the file available at the link below there is a [Source] worksheet on which you will find an input table that is set up to accept input that closely resembles your initial post. Ideally this input table or your source table will be adjusted so that their structures are identical, in which case Step 1 below will be straightforward. To obtain the solution, follow these six steps (references refer to those on sheet [Source] unless otherwise noted):

1. Copy monthly data and paste into cells F6:K6 and down. If data contain formulas, use Paste Special > Values instead.
2. Review column L and ensure that a 1 appears for each item to consider in the analysis. Generally, line items having a Charge=0 should not be considered in the analysis, so the 1 would be deleted on that row in column L. Ensure any other rows to avoid also have a blank in column L.
3. Formulas in the table compute the weighted sums of Building A and Building D charges (M6:N6 and down). Copy the ideal weighted sum for Bldg A in cell M4 and Paste Special > Value into cell C2.
4. Formulas prepare the input data set for the VBA code. Copy Q6:R6 and down and Paste Special > Values into A2:B2 and down. Delete anything below the new pasted information in columns A:B.
5. Run the VBA code: Developer>Macros>Control3.
6. Results are returned to the [Results] worksheet. A backend analysis utility is in columns V:Y. Of all results returned to the [Results] sheets, only those whose sum is within some tolerance zone of the target are brought forward onto this worksheet. Adjust the tolerance in cell V1 to reduce or expand the number of results carried onto this sheet. Formulas then identify the first best set of KeyCodes whose sum is closest to the Target and the results appear in the blue results table S5:T5 and down.

There are a few copy/paste special operations, but the entire process should only take a minute or so to generate the answer. You may need to activate the Developer tab so that you can run the VBA code. The code is included and ready to run in the workbook. Please post back if you have any questions or encounter any issues.

MrExcel_20220814_CombinatoricsSum_Approach3.xlsm

Shared with Dropbox

www.dropbox.com

 

[Xlambda]

Xlambda - I apologize for the long delay in answering - but D365 has been killing me, and I've not had time to look at anything.

I absolutely invite you to post under your thread, and will definitely go to look at it. However, I think this has hit the point that I've given up on the macro idea. Instead, what I've done is created a toggle, where I have a column where the actual charges are added, and then another column where charges add up according to whether I toggle the charge to go to A or D. At the top, a box tells me how close I am to the actual charge, and I just play with the numbers. For my July charges, I had about 90 charges, and actually was able to toggle the charges until I got them to $3.69 of the actual.

Meanwhile, thank you to everyone who tried to help me through this!

Problem recap: We have an array of values "a" and we need to find a group of them, that has "gr" elements that summed up will be as close as possible to a target value "tg".
I think your problem has a much more simpler solution, since your acceptable margin of error is quite large (3.98 is huge)
If you have like 90-100 charges/month, combinatorics accurate approach is too much for excel in many ways.
If the grouping array has let's say gr=40 elements (less than half of tot charges/month), total combinations w/o repetitions (since we need the sum, order is not important) will be:
=COMBIN(90,40) =5.98709086469727E+25
If excel needs 1E-20 sec for each calculation total calc time will be:
=5.98709086469727E+25*1E-20/60/60/24 =6.9 days
Instead of calculating all possible combinations we can generate a consistent nr. of random index distributions "ni" (without repetitions) of "gr" elements each and calculate the error margin for the sum of each of them, choosing one with the smallest margin to the target "tg" and displaying the results.
RSGT(a,tg,[ni],[ng]) Random Sum Group Target
a: array of charges
tg: target value
[ni]: nr. of iterations (nr. of random index distributions)
- if omitted ni=10000, or, for greater chances of smaller error margins we can use 30000 or more, calc time for 10000 aprox 1 sec
[gr]: grouping nr. of elements
- if omitted, gr will be estimated gr=int(tg/average(a)), otherwise we can introduce a dif value

=LAMBDA(a, tg, [ni], [gr],
    LET(
        r, ROWS(a),
        g, IF(gr, gr, INT(tg / AVERAGE(a))),
        n, IF(ni, ni, 10000),
        ia, LAMBDA(INDEX(SORTBY(SEQUENCE(r), RANDARRAY(r)), SEQUENCE(g))),
        m, MAP(
            SEQUENCE(n),
            LAMBDA(x,
                LET(
                    y, SORT(ia()),
                    z, INDEX(a, y),
                    s, ABS(SUM(z) - tg),
                    TEXTJOIN(",", , s, y)
                )
            )
        ),
        f, INDEX(SORT(m), 1, 1),
        x, --TEXTSPLIT(f, , ","),
        y, INDEX(a, DROP(x, 1)),
        HSTACK(x, VSTACK("val", y))
    )
)

Random SUM grouping target.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U
1		a: random generated with formula =ROUND(RANDARRAY(100,,1,100),2) 100 values btwn 1 min and 100 max
2						spin?
3						n	<= if "y" function recalculates, if "n" freezes										helper column for CF of "a"
4		a		target "tg"													=IFNA(XMATCH(SEQUENCE(ROWS(B5:B104)),F7:F45),0)
5		42.82		1735.24		=IF(F3="y",RSGT(B5:B104,D5),F6#)			<= formula to prevent RSGT to recalculate								0
6		10.98				0.01	val										0
7		18.9				6	89.71		result array elements								0
8		15.45				7	66.85		- top left cell, smallest error margin of all index distributions								0
9		62.13		sum "a"		9	23.94		- 1st column, indexes values ascending order that correspond to smalles error margin								0
10		89.71		5102.7		10	77.74		- 2nd column, values extraction of "a" correspondent to matching indexes								1
11		66.85				12	56.12										2
12		98.51		default gr estimation		26	87.32										0
13		23.94		=INT(D5/AVERAGE(B5:B104))		27	95.25		check gr								3
14		77.74		34		32	82.35		=ROWS(F6#)-1								4
15		86.17				34	84.61		34								0
16		56.12				36	12.64										5
17		9.3				41	11.87		check error margin								0
18		13.31				43	1.93		=ABS(SUM(INDEX(F6#,,2))-D5)								0
19		4.54				44	43.31		0.01								0
20		95.04				46	80.28										0
21		38.29				48	15.84										0
22		18.03				49	29.15										0
23		68.26				52	33.03										0
24		30.44				56	56.99										0
25		88.25				57	80.32										0
26		93.8				59	12.89										0
27		97.84				62	91.98										0
28		95.58				67	23.69										0
29		1.09				68	68.82										0
30		87.32				71	37.02										6
31		95.25				74	28.21										7
32		21.59				75	78.54										0
33		56.76				76	53.95										0
34		99.78				77	58.92										0
35		62.55				79	64.75										0
36		82.35				81	17.29										8
37		31.84				85	19.87										0
38		84.61				86	52.36										9
39		73.51				94	33.52										0
40		12.64				98	64.17										10
41		32.28															0
42		64.93															0
43		80.05															0
44		38.46															0
45		11.87															11
46		2.78															0
47		1.93															12
48		43.31															13
49		24.47															0
50		80.28															14
51		69.87															0
52		15.84															15
53		29.15															16
54		28.55															0
55		35.02															0
56		33.03															17
57		18.02															0
58		50.27															0
59		62.52															0
60		56.99															18
61		80.32															19
62		94.05															0
63		12.89															20
64		46.88															0
65		7.96															0
66		91.98															21
67		69.52															0
68		71.29															0
69		49.97															0
70		29.32															0
71		23.69															22
72		68.82															23
73		88.33															0
74		75.94															0
75		37.02															24
76		38.97															0
77		55.45															0
78		28.21															25
79		78.54															26
80		53.95															27
81		58.92															28
82		55.86															0
83		64.75															29
84		89.55															0
85		17.29															30
86		1.34															0
87		81.08															0
88		26.85															0
89		19.87															31
90		52.36															32
91		35.09															0
92		11.09															0
93		62.62															0
94		87.17															0
95		47.52															0
96		67.26															0
97		38.72															0
98		33.52															33
99		57.75															0
100		68.42															0
101		82.05															0
102		64.17															34
103		7.71															0
104		77.73															0
105
Sheet1

Cell Formulas
Range	Formula
Q4,I18,I14,D13,F5	Q4	=FORMULATEXT(Q5)
Q5:Q104	Q5	=IFNA(XMATCH(SEQUENCE(ROWS(B5:B104)),F7:F45),0)
F6:G40	F6	=IF(F3="y",RSGT(B5:B104,D5),F6#)
D10	D10	=SUM(B5:B104)
D14	D14	=INT(D5/AVERAGE(B5:B104))
I15	I15	=ROWS(F6#)-1
I19	I19	=ABS(SUM(INDEX(F6#,,2))-D5)
Dynamic array formulas.

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
B5:B104	Expression	=Q5	text	NO
F6:G106	Expression	=--F6<>0	text	NO

 

[Xlambda]

To reveal how simple the concept and the function is, will unfold RSGT functionality in 2 parts, step by step.
Part 1, about initial variables and index array embedded lambda ia()
r,g,n variables quite straight forward
r, ROWS(a)
g, IF(gr, gr, INT(tg / AVERAGE(a))) if gr omitted g=int(tg/average(a)), if not assigns input value
n, IF(ni, ni, 10000) if ni omitted n=10000 , if not assigns input value
ia, LAMBDA(INDEX(SORTBY(SEQUENCE(r), RANDARRAY(r)), SEQUENCE(g)))
- ia(), embedded lambda function, argument free function, creates a single random distribution (no duplicates) of "g" elements of index nr. btw 1 and rows(a)

Random SUM grouping target.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1
2		ia() functionality		example for r=20, g=12
3
4		r,20				random sorting		g,12
5		array indexes				no dups		extracting only g=12 group elements
6		=SEQUENCE(20)		=RANDARRAY(20)		=SORTBY(B7#,D7#)		=INDEX(F7#,SEQUENCE(12))
7		1		0.358821		4		4
8		2		0.338573		19		19		checking no dups
9		3		0.789528		15		15		=ROWS(UNIQUE(H7#))=12
10		4		0.064648		18		18		TRUE
11		5		0.70475		17		17
12		6		0.545774		2		2
13		7		0.933094		1		1
14		8		0.439253		12		12
15		9		0.518712		13		13
16		10		0.63981		8		8
17		11		0.831632		20		20
18		12		0.401736		9		9
19		13		0.40421		6
20		14		0.714475		10		calling ia() for r=20, g=12
21		15		0.095864		5		=LAMBDA(INDEX(SORTBY(SEQUENCE(20), RANDARRAY(20)), SEQUENCE(12)))()
22		16		0.917692		14		7
23		17		0.30919		3		18
24		18		0.128829		11		13
25		19		0.095471		16		15
26		20		0.482232		7		11
27								16
28								5
29								10
30								3
31								1
32								14
33								12
34
Sheet2

Cell Formulas
Range	Formula
B6,D6,F6,H6,H21,J9	B6	=FORMULATEXT(B7)
B7:B26	B7	=SEQUENCE(20)
D7:D26	D7	=RANDARRAY(20)
F7:F26	F7	=SORTBY(B7#,D7#)
H7:H18	H7	=INDEX(F7#,SEQUENCE(12))
J10	J10	=ROWS(UNIQUE(H7#))=12
H22:H33	H22	=LAMBDA(INDEX(SORTBY(SEQUENCE(20), RANDARRAY(20)), SEQUENCE(12)))()
Dynamic array formulas.

 

[Xlambda]

Part 2, m variable using MAP, plus final cosmetic calculations.
m,MAP(SEQUENCE(n ),LAMBDA(x,LET(y,SORT(ia()),z,INDEX(a,y),s,ABS(SUM(z)-tg),TEXTJOIN(",",,s,y))))
For each cell contained in MAP array, the lambda helper functions applies same calculations.
Note: for simplicity I have defined ia()=LAMBDA(INDEX(SORTBY(SEQUENCE(20), RANDARRAY(20)), SEQUENCE(12)))

Random SUM grouping target.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V
1
2				for a single cell of array contained in MAP
3								target ex:
4								630
5		a		sort(ia())		"a" index values
6		83		=SORT(ia())		=INDEX(B6#,D7#)
7		72		2		72		evaluating error margin
8		13		3		13		=ABS(SUM(F7#)-H4)
9		66		5		37		74
10		37		6		64
11		64		8		40		since MAP can return a single result for each of its cells, we have to textjoin the relevant data
12		5		9		57		- first value to the left, error margin followed by respective index distribution, ascending order
13		40		11		13
14		57		12		76			=TEXTJOIN(",",,H9,F7#)
15		77		14		51			74,72,13,37,64,40,57,13,76,51,6,79,48
16		13		15		6
17		76		16		79		- as we see, for a single random distribution of 12 grouped indexes, error margin is large
18		95		17		48		- with MAP we can do this n (ni) times. For n=2000 times, sorting the result and extracting first 10 for visual relevance
19		51
20		6							=LET(m,MAP(SEQUENCE(2000),LAMBDA(x,LET(y,SORT(ia()),z,INDEX(B6#,y),s,ABS(SUM(z)-H4),TEXTJOIN(",",,s,y)))),INDEX(SORT(m),SEQUENCE(10)))
21		79							0,1,2,3,4,7,8,10,13,14,16,17,18
22		48							0,1,2,3,7,10,11,12,13,15,16,19,20		- the function extracts only first value (smallest error margin)
23		1							0,1,2,4,5,6,9,10,11,16,17,18,20		expanding 1st cell						final result
24		78							0,1,2,4,7,8,9,12,13,14,15,18,19		=--TEXTSPLIT(I21,,",")		only indexes		index matching		=HSTACK(K25#,VSTACK("val",O26#))
25		33							0,1,3,4,5,6,8,9,10,11,13,15,16		0	<- err margin	=DROP(K25#,1)		=INDEX(B6#,M26#)		0	val
26									0,2,3,4,6,7,12,13,16,17,18,19,20		1		1		83		1	83		err checking
27									1,1,2,3,4,6,7,8,11,13,14,16,17		2		2		72		2	72		=ABS(SUM(R26:R37)-H4)
28									1,1,2,3,4,8,11,13,14,15,16,19,20		3		3		13		3	13		0
29									1,1,2,3,5,9,10,12,14,15,17,19,20		4		4		66		4	66
30									1,1,2,3,8,9,10,12,14,17,18,19,20		7		7		5		7	5
31											8		8		40		8	40
32											10		10		77		10	77
33											13		13		95		13	95
34											14		14		51		14	51
35											16		16		79		16	79
36											17		17		48		17	48
37											18		18		1		18	1
38
Sheet3

Cell Formulas
Range	Formula
B6:B25	B6	=RANDARRAY(20,,1,100,1)
D6,F6,T27,M25,O25,Q24,K24,I20,I14,H8	D6	=FORMULATEXT(D7)
D7:D18	D7	=SORT(ia())
F7:F18	F7	=INDEX(B6#,D7#)
H9	H9	=ABS(SUM(F7#)-H4)
I15	I15	=TEXTJOIN(",",,H9,F7#)
I21:I30	I21	=LET(m,MAP(SEQUENCE(2000),LAMBDA(x,LET(y,SORT(ia()),z,INDEX(B6#,y),s,ABS(SUM(z)-H4),TEXTJOIN(",",,s,y)))),INDEX(SORT(m),SEQUENCE(10)))
K25:K37	K25	=--TEXTSPLIT(I21,,",")
Q25:R37	Q25	=HSTACK(K25#,VSTACK("val",O26#))
M26:M37	M26	=DROP(K25#,1)
O26:O37	O26	=INDEX(B6#,M26#)
T28	T28	=ABS(SUM(R26:R37)-H4)
Dynamic array formulas.

 

[Xlambda]

Random SUM grouping target.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
1	crazy example 'a' 500 rows, 30000 iterations , error margin =0.0399999999935972								a formula:		=ROUND(RANDARRAY(500,,1,1000),2)				min val 1, max val 1000
2	- time calculation		7 sec
3					target				all pos combinations			1 iter.=1E-100 s
4					99999.99				=COMBIN(500,208)			=I5*1E-100/60/60/24/365/1000000
5		a							9.8738E+145			3.13095E+32
6		221.54										tot calc time in milion years
7		936.66		=RSGT(B6:B505,E4,30000)								fun estimation
8		7.32		0.04	val		estimated
9		855.49		2	936.66		gr number		check error
10		662.52		6	289.3		=ROWS(D8#)-1		=ABS(SUM(E9:E216)-E4)
11		289.3		10	117.58		208		0.04
12		226.44		11	85.66
13		90.61		13	953.27		rows check a
14		153.83		17	905.64		=ROWS(B6:B505)
15		117.58		21	540.19		500
16		85.66		22	13.9
17		34.06		27	639.2
18		953.27		31	328.44
19		524.63		33	501.92
20		571.21		34	886.71
21		168.83		35	90.96
22		905.64		37	508.67
23		359.83		39	914.81
24		147.29		42	939.7
25		749.26		53	15.15
26		540.19		54	151.83
27		13.9		57	43.45
28		845.77		62	289.09
29		710.08		63	533.91
30		811.12		69	648.45
31		184.58		70	825.2
32		639.2		73	466.27
33		230.54		77	242.23
34		85.7		78	178.47
35		176.5		83	894.59
36		328.44		84	361.36
37		526.65		86	502.19
38		501.92		88	644.48
39		886.71		92	306.87
40		90.96		93	39.04
41		169.22		95	609.37
42		508.67		97	413.83
43		945.3		101	441.51
44		914.81		106	990.94
45		183.37		111	155.88
46		917.8		112	634.62
47		939.7		113	659.15
48		311.8		118	510.24
49		650.31		126	733.04
50		30.61		130	358.81
51		654.53		131	807.95
52		708.24		134	527.43
53		366.54		136	126.4
54		842.26		138	462.63
55		955.81		140	287.29
56		877.26		142	126.97
57		381.2		144	234.91
58		15.15		146	835.38
59		151.83		148	321.99
60		180.11		149	146.08
Sheet5

Cell Formulas
Range	Formula
A1	A1	="crazy example 'a' 500 rows, 30000 iterations , error margin ="&D8
I4,G14,G10,I10,D7,L4	I4	=FORMULATEXT(I5)
I5	I5	=COMBIN(500,208)
L5	L5	=I5*1E-100/60/60/24/365/1000000
D8:E216	D8	=RSGT(B6:B505,E4,30000)
G11	G11	=ROWS(D8#)-1
I11	I11	=ABS(SUM(E9:E216)-E4)
G15	G15	=ROWS(B6:B505)
Dynamic array formulas.