Checking size of file on web server...

[RobbieC]

Hi there, I trying to write a script to compare filesizes of local and remote (on a web server) files...

I can get the local filesize by using:

Dim localFileSize As Long
localFileSize = FileLen(ThisWorkbook.Path  & Filename)

MsgBox "local - " & localFileSize

I can check if my 'remote' file exists by using:

Dim doesFileExist As Boolean
doesFileExist = checkFile("http://www.mywebserver.com/files/" & Filename)
MsgBox "Remote file exists - " & doesFileExist

which returns a true or false. But for the life of me I can't return the filesize of the file on the remote server....

If you can point me in the right direction, I'd be extremely happy

Thanks

 

[RobbieC]

doh... my mind is fuddled! It was such a long time ago that I put all this code together...

The function checkfile is:

Function checkFile(ByRef sURL As String) As Boolean


Dim oXHTTP As Object
Set oXHTTP = CreateObject("MSXML2.XMLHTTP")
oXHTTP.Open "HEAD", sURL, False
oXHTTP.Send
    If oXHTTP.Status = 200 Then
        'FileSize = oXHTTP.getResponseHeader("Content-Length")
        'MsgBox "exists" & sURL
        checkFile = True
    Else
        'FileSize = -1
        'MsgBox "doesn't exist" & sURL
        checkFile = False
    End If


End Function

FileSize is commented out.... So would I do something like:

Dim remoteFileSize As Long
remoteFileSize = checkFile("[COLOR=#333333]http://www.mywebserver.com/files/" & Filename[/COLOR])
MsgBox remoteFileSize

 

[Kyle123]

Yes, but to prevent 2 calls, you may want something like:

Function checkFile(ByVal sURL As String, Optional ByRef fileSize as Long) As Boolean


    Static oXHTTP As Object
    
    if oXHTTP is Nothing then Set oXHTTP = CreateObject("MSXML2.XMLHTTP")
    
    fileSize = 0
    
    oXHTTP.Open "HEAD", sURL, False
    oXHTTP.Send
    If oXHTTP.Status = 200 Then
        fileSize = Val(oXHTTP.getResponseHeader("Content-Length"))
        'MsgBox "exists" & sURL
        checkFile = True
    Else
        fileSize = 0
        'MsgBox "doesn't exist" & sURL
        checkFile = False
    End If


End Function

That would then be called:

Dim remoteFileSize As Long
Dim doesFileExist As Boolean
doesFileExist = checkFile("http://www.mywebserver.com/files/" & Filename, remoteFileSize)
MsgBox remoteFileSize
MsgBox doesFileExist

This then requires a singe http request to get the file size and checks whether it exists. The web server may not always return the file size should the file exist, so you need to check the status.

If the file doesn't exist or there is no length returned the file size will be zero.

Note that the fileSize is optional, so that this will not break any existing code that passes one parameter and expects a boolean result

 

[RobbieC]

BRILLIANT!

Thanks Kyle - works a treat!!! Happy days!!!