Check if a pdf reader is installed on a pc

[kelly mort]

I have been searching the Web for solutions. I have seen a few examples of how to check if an Adobe Reader is installed but what I want is to be able to check if any pdf reader at all is installed.
This from excel forum:

How to check if Adobe Acrobat Reader was installed on your computer or not? [SOLVED]

Hi beautiful people, How to check if Adobe Acrobat Reader was installed on your computer or not? I need a vba code for this. Best wishes.

www.excelforum.com

I also came across this post on stack overflow:

Check if there is any kind of PDF Reader installed

I have a Help function in my Application, that consists of one webbrowser control. That webbrowser control gets filled with a .pdf file, the source for that .pdf file is our own website. The probl...

stackoverflow.com

Which is not VBA code though.

Can someone help me with how to use VBA to check if any pdf reader is installed?
Thanks in advance.

 

[Logit]

Your first link works here : How to check if Adobe Acrobat Reader was installed on your computer or not? [SOLVED]

That macro is checking for the Reader version of Adobe ... not the full fledged version of Adobe.

 

[kelly mort]

Bump:

Cross posted at:

Check if a pdf reader is installed on a pc with VBA [SOLVED]

Cross posted at: https://www.mrexcel.com/board/threads/check-if-a-pdf-reader-is-installed-on-a-pc.1191618/ Reason: It has not been solved yet. I have been searching the Web for solutions. I have seen a few examples of how to check if an Adobe Reader is installed but what I want is to be...

www.excelforum.com

 

[Jaafar Tribak]

When you say any PDF reader, do you mean any software that can read PDF files ? If so, it is difficult because that includes a long list of software such as Word, Internet Explorer and many others etc

 

[kelly mort]

Yes, I mean any software that can read pdf.
I was thinking there could be an attribute or something that could identify such programs.
Because looking at the conversation here:

Check if there is any kind of PDF Reader installed

I have a Help function in my Application, that consists of one webbrowser control. That webbrowser control gets filled with a .pdf file, the source for that .pdf file is our own website. The probl...

stackoverflow.com

It looked as if there was a way (I didn't understand most of the discussions though).

But if there is a way to check for the most popular ones I would be grateful to get the way around it.

 

[Jaafar Tribak]

Yes, I mean any software that can read pdf.
But if there is a way to check for the most popular ones I would be grateful to get the way around it.

I think the best way is to use file association but, for that, we first need to know the most popular file extensions of the document files created by PDF Viewers\Readers which I don't know.

We could assume that all documents with a .pdf extension are by default, opened with the most popular PDF Viewers\Readers such as Adobe Reader or Adobe Acrobat but, although this may be the case most of the time , it is not strictly true.

Anyway, here is this code:

In a Standard Module:

Option Explicit

Private Enum ASSOC_FILTER
    ASSOC_FILTER_NONE = &H0
    ASSOC_FILTER_RECOMMENDED = &H1
End Enum

#If VBA7 Then
    Private Declare PtrSafe Function SHAssocEnumHandlers Lib "shell32" (ByVal pszExtra As LongPtr, ByVal afFilter As ASSOC_FILTER, ByVal ppEnumHandler As LongPtr) As Long
    Private Declare PtrSafe Function DispCallFunc Lib "oleAut32.dll" (ByVal pvInstance As LongPtr, ByVal offsetinVft As Long, ByVal CallConv As Long, ByVal retTYP As Integer, ByVal paCNT As Long, ByRef paTypes As Integer, ByRef paValues As LongPtr, ByRef retVAR As Variant) As Long
    Private Declare PtrSafe Sub SetLastError Lib "kernel32.dll" (ByVal dwErrCode As Long)
    Private Declare PtrSafe Function SysReAllocString Lib "oleAut32.dll" (ByVal pBSTR As LongPtr, Optional ByVal pszStrPtr As LongPtr) As Long
#Else
    Private Declare Function SHAssocEnumHandlers Lib "shell32" (ByVal pszExtra As Long, ByVal afFilter As ASSOC_FILTER, ByVal ppEnumHandler As Long) As Long
    Private Declare Function DispCallFunc Lib "oleAut32.dll" (ByVal pvInstance As Long, ByVal offsetinVft As Long, ByVal CallConv As Long, ByVal retTYP As Integer, ByVal paCNT As Long, ByRef paTypes As Integer, ByRef paValues As Long, ByRef retVAR As Variant) As Long
    Private Declare Sub SetLastError Lib "kernel32.dll" (ByVal dwErrCode As Long)
    Private Declare Function SysReAllocString Lib "oleAut32.dll" (ByVal pBSTR As Long, Optional ByVal pszStrPtr As Long) As Long
#End If


Public Function Is_PDF_Reader_Installed() As Boolean
    Is_PDF_Reader_Installed = Len(FindExecutable_With_AssocHandlerINTERFACE("pdf"))
End Function

Private Function FindExecutable_With_AssocHandlerINTERFACE(ByVal DocumetFileExtension As String) As String

    #If Win64 Then
        Const vTblOffsetFac_32_64 = 2&
        Dim pEnumHandlers As LongLong
        Dim pAssocHandler As LongLong
         Dim pceltFetched As LongLong
        Dim pExecutablePathName As LongLong
    #Else
        Const vTblOffsetFac_32_64 = 1&
        Dim pEnumHandlers As Long
        Dim pAssocHandler As Long
        Dim pceltFetched As Long
        Dim pExecutablePathName As Long
    #End If
 
    Const IEnumAssocHandlers_Next = 12 * vTblOffsetFac_32_64
    Const IAssocHandler_GetName = 12 * vTblOffsetFac_32_64
    Const CC_STDCALL = 4&
    Const S_OK = 0&
 
    Dim Unk As IUnknown

    If Len(DocumetFileExtension) Then
        DocumetFileExtension = IIf(Left(DocumetFileExtension, 1) = ".", DocumetFileExtension, "." & DocumetFileExtension)
        If SHAssocEnumHandlers(StrPtr(DocumetFileExtension), ASSOC_FILTER_RECOMMENDED, VarPtr(Unk)) = S_OK Then
            pEnumHandlers = ObjPtr(Unk)
            If vtblCall(pEnumHandlers, IEnumAssocHandlers_Next, vbLong, CC_STDCALL, 1&, VarPtr(pAssocHandler), VarPtr(pceltFetched)) = S_OK Then
                If vtblCall(pAssocHandler, IAssocHandler_GetName, vbLong, CC_STDCALL, VarPtr(pExecutablePathName)) = S_OK Then
                    FindExecutable_With_AssocHandlerINTERFACE = GetStrFromPtrW(pExecutablePathName)
                End If
            End If
        End If
    End If

End Function

#If Win64 Then
    Private Function vtblCall(ByVal InterfacePointer As LongLong, ByVal VTableOffset As Long, ByVal FunctionReturnType As Long, ByVal CallConvention As Long, ParamArray FunctionParameters() As Variant) As Variant

    Dim vParamPtr() As LongLong
#Else
    Private Function vtblCall(ByVal InterfacePointer As Long, ByVal VTableOffset As Long, ByVal FunctionReturnType As Long, ByVal CallConvention As Long, ParamArray FunctionParameters() As Variant) As Variant

    Dim vParamPtr() As Long
#End If

    If InterfacePointer = 0& Or VTableOffset < 0& Then Exit Function
    If Not (FunctionReturnType And &HFFFF0000) = 0& Then Exit Function

    Dim pIndex As Long, pCount As Long
    Dim vParamType() As Integer
    Dim vRtn As Variant, vParams() As Variant

    vParams() = FunctionParameters()
    pCount = Abs(UBound(vParams) - LBound(vParams) + 1&)
    If pCount = 0& Then
        ReDim vParamPtr(0 To 0)
        ReDim vParamType(0 To 0)
    Else
        ReDim vParamPtr(0 To pCount - 1&)
        ReDim vParamType(0 To pCount - 1&)
        For pIndex = 0& To pCount - 1&
            vParamPtr(pIndex) = VarPtr(vParams(pIndex))
            vParamType(pIndex) = VarType(vParams(pIndex))
        Next
    End If
 
    pIndex = DispCallFunc(InterfacePointer, VTableOffset, CallConvention, FunctionReturnType, pCount, vParamType(0), vParamPtr(0), vRtn)
    If pIndex = 0& Then
        vtblCall = vRtn
    Else
        SetLastError pIndex
    End If

End Function

#If Win64 Then
    Private Function GetStrFromPtrW(ByVal Ptr As LongLong) As String
#Else
    Private Function GetStrFromPtrW(ByVal Ptr As Long) As String
#End If

    SysReAllocString VarPtr(GetStrFromPtrW), Ptr

End Function

Usage Example :

Sub Test()
    MsgBox Is_PDF_Reader_Installed
End Sub

 

[kelly mort]

Oh okay. I now get why you asked the first question.

I Uninstalled my pdf reader and it was still returning true:

So when I tried to open the pdf file (searching for program from installed list), word showed up.

Is it possible to bypass that - that's eliminating word from the list (my choice of pdf readers).

With broswers, I am okay.

I want to eliminate word since it has to convert the document, mostly changing the structure of it.

 

[Jaafar Tribak]

Now that you have pdf reader uninstalled, can you change the Is_PDF_Reader_Installed function as follows:

Public Function Is_PDF_Reader_Installed() As Boolean
    Debug.Print FindExecutable_With_AssocHandlerINTERFACE(".pdf")
    Is_PDF_Reader_Installed = Len(FindExecutable_With_AssocHandlerINTERFACE(".pdf"))
End Function

Now, when you run the Test macro, what string do you get in the immediate window ?

 

[kelly mort]

This is what I get:

C:\Program Files (x86) \Microsoft Office \Root\Office16\Winword.exe

 

[Jaafar Tribak]

This is what I get:

C:\Program Files (x86) \Microsoft Office \Root\Office16\Winword.exe

In that case, change the Is_PDF_Reader_Installed as follows in order to exclude WinWord.exe

Public Function Is_PDF_Reader_Installed() As Boolean

    Dim sExecutablePath As String

    sExecutablePath = FindExecutable_With_AssocHandlerINTERFACE(".PDF")
   
    If Len(sExecutablePath) And UCase(Right(sExecutablePath, 11)) <> UCase("WINWORD.EXE") Then
        Is_PDF_Reader_Installed = True
    End If

End Function