Cannot SetFocus > userform control

[Jon von der Heyden]

Hi All

Posting a rather lengthy class here. Everything works as expected, except the .SetFocus line. Testing on textboxes, the control in question is not selected, yet the error message displays:

clsFormsControlsEvents:

Private WithEvents m_TextBoxEvents As MSForms.TextBox
Private WithEvents m_ComboBoxEvents As MSForms.ComboBox
Private m_blnOk As Boolean 'boolean to tell us whether or not all controls ok

Public Property Set Control(ctlNew As MSForms.Control)
    Select Case TypeName(ctlNew)
        Case "TextBox"
            Set m_TextBoxEvents = ctlNew
        Case "ComboBox"
            Set m_ComboBoxEvents = ctlNew
    End Select
End Property

'there's no exit event, so we use key/mouse down events, check for tab and click to a different control

Private Sub m_TextBoxEvents_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    If KeyCode = vbKeyTab Then
        Call ControlEventTriggered(m_TextBoxEvents)
    End If
End Sub

Private Sub m_TextBoxEvents_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)

End Sub

Private Sub ControlEventTriggered(ByVal ctl As MSForms.Control)
    Dim varArrTag As Variant
    varArrTag = Split(ctl.Tag, ",")
    'tag: (0) = Mandatory boolean
    '     (1) = Data type
    '     (2) = Length
    
    With ctl
        If varArrTag(0) = True And Len(.Object.Value) = 0 Then
            [COLOR=Red][B].SetFocus[/B][/COLOR]
            MsgBox Prompt:="Mandatory field!", Buttons:=vbExclamation + vbOKOnly, Title:=ctl.Parent.Name
            m_blnOk = False
            GoTo Finally
        End If
        Select Case varArrTag(1)
            Case "date"
                If Not IsDate(.Object.Value) Then
                    [COLOR=Red][B].SetFocus[/B][/COLOR]
                    MsgBox Prompt:="Invalid date!", Buttons:=vbExclamation + vbOKOnly, Title:=ctl.Parent.Name
                    m_blnOk = False
                    GoTo Finally
                End If
            Case "numeric"
                If Not IsNumeric(.Object.Value) Then
                    [COLOR=Red][B].SetFocus[/B][/COLOR]
                    MsgBox Prompt:="Number field!", Buttons:=vbExclamation + vbOKOnly, Title:=ctl.Parent.Name
                    m_blnOk = False
                    GoTo Finally
                End If
            'more cases here
        End Select
        If Len(.Object.Value) > CLng(varArrTag(2)) Then
            [COLOR=Red][B].SetFocus[/B][/COLOR]
            MsgBox Prompt:="Max " & varArrTag(2) & " chars!", Buttons:=vbExclamation + vbOKOnly, Title:=ctl.Parent.Name
            m_blnOk = False
            GoTo Finally
        End If
    End With
    
    m_blnOk = True
    
Finally:
    Erase varArrTag
End Sub

Private Sub Class_Terminate()
    Set m_TextBoxEvents = Nothing
    Set m_ComboBoxEvents = Nothing
    m_blnOk = Empty
End Sub

 

[Michael Simpson]

Having pasted in the code, I'm not good enough to understand how I'm supposed to incorporate it into the rest of my userform code.

Could you elaborate please ?

 

[RoryA]

The Exit event (and Enter and Before/AfterUpdate) actually belong to the container Control and not to the textbox, hence they are not available. You also cannot use a WithEvents MSForms.Control variable, I'm afraid.

 

[RoryA]

Having pasted in the code, I'm not good enough to understand how I'm supposed to incorporate it into the rest of my userform code.

Could you elaborate please ?

Since I have no idea what your code is, no not really.

 

[Jon von der Heyden]

The Exit event (and Enter and Before/AfterUpdate) actually belong to the container Control and not to the textbox, hence they are not available.

Ah, that makes sense. Although I don't know why they belong to the container Control!

You also cannot use a WithEvents MSForms.Control variable, I'm afraid.

Tried that too, and failed miseraby!

But all-in-all this works as expected now. Next step is to use the MouseDown event and test if the co-ordinate is outside of the current control.

Thanks again!

 

[RoryA]

But all-in-all this works as expected now. Next step is to use the MouseDown event and test if the co-ordinate is outside of the current control.

Huh?

 

[Jon von der Heyden]

I've never programmed a mousedown even before, but I thought you use the XY coordinates to check where the mouse has been clicked. So far I am handling the user using Tab to navigate to another control, but the user might also use the mouse to move to a different control, in which case I need to run the same routine.

 

[RoryA]

But the event will only be triggered for a control if the click is within it.

 

[Jon von der Heyden]

But the event will only be triggered for a control if the click is within it.

Bit of a dumb moment there!

So, in order to trap a user moving away from the control with the mouse, do I need to keep track of what the previous control was? That makes it more complicated!

 

[RoryA]

Yep - you'll need to store that in a variable as you move from control to control.

 

[Jon von der Heyden]

Thanks Rory.

Last question, is it possible to create my own custom exit event that incorporates both methods (i.e. tab away and mouse away)? And if so do you know of anywhere that illustrates something similar that you can point me to?