Cannot pull table from different tabs within the same webpage.

[mj sachoo]

Hello,

I am trying to obtain the data table from

Australia Stock Market - Investing.com AU

Up-to-date data on the stock market in Australia, including leading stocks, large and small cap stocks.

au.investing.com

website. However, I can only extract the data from the 'Price' tab.

I cannot obtain the tables under the 'Performance', 'Technical and 'Fundamental Tabs.

I get the following error when trying to click the other tabs:

I do not know how to get these tables from other tabs.

Last hope is this website as I have not got anything from other forums or websites.

Please advise.

Thanks

 

[Abdmujib]

Thank you for the response, yeah the link has broken, I always change the number in the link, the number signifies the season. this is the new link "Tables, Virtual Football League Mode 26352, Virtual Football, Soccer" .
i understand the thread is old but I'd have to begin afresh if I start a new thread and moreso I won't be able to tag you to the new thread. thansk

 

[Anthony47]

Having preset the Selenium environment (Selenium basic & browser driver) you should be able to import all the tables presented by that site using the following code:

Sub SeleniumSportradar()
Dim TbColl As Object, tArr, myItm As Object
Dim I As Long, J As Long, myTim As Single
Dim WPage As Object
Dim myUrl As String
'
'CONFIGURATION:
myUrl = https://s5.sir.sportradar.com/bet9javirtuals/en/1/season/2403775/standings     '<<< The web page
Sheets("Tables").Select                     '<<< The sheet to use
Range("A:T").ClearContents                  '<<< Clear the sheet?
'
myTim = Timer
Set WPage = CreateObject("Selenium.WebDriver")
WPage.Start "Chrome", myUrl                         ' <11
''WPage.Start "edge", myUrl                          ' <22
WPage.Get "/"
'
On Error Resume Next
J = Range("A:T").Find(What:="*", After:=Range("A1"), _
              SearchOrder:=xlByRows, _
              SearchDirection:=xlPrevious).Row
On Error GoTo 0
J = J + 2
Debug.Print vbCrLf & "Start", "J= " & J, WPage.Url, Format(Timer - myTim, "0.00")
Set TbColl = WPage.FindElementsByTag("table")
Debug.Print "Tables found: " & TbColl.Count, Format(Timer - myTim, "0.00")
For I = 1 To TbColl.Count
    Cells(J, 2).Value = "Table #" & I
    tArr = TbColl(I).AsTable.Data
    Cells(J + 1, 1).Resize(UBound(tArr), UBound(tArr, 2)).Value = tArr
    Debug.Print "Table #" & I, UBound(tArr) & " * " & UBound(tArr, 2)
    J = J + UBound(tArr) + 3
Next I
'
Debug.Print "END", I, J, Format(Timer - myTim, "0.00")
WPage.Quit
MsgBox ("Collected...")
End Sub

The main "configuration" is set at the beginning of the macro; see the instructions marked <<<
The same macro should work with any url that presents its data as Tables.

When you are ready, run Sub SeleniumSportradar; it will select the target sheet and clear it (if clear has not been removed); then open a new session of Chrome, read the page, import the tables

 

[Abdmujib]

Thank you Anthony

 

[Abdmujib]

The code is not working, says "syntax". Also the last code we run with excel (thread No 14) we created two sheet AAA and BBB so I could import the home and away table separately. this one doesn't have

 

[Anthony47]

Please clarify which error you get and on which line.

Also the last code we run with excel (thread No 14) we created two sheet AAA and BBB so I could import the home and away table separately. this one doesn't have

In message #20 I asked "which is the target url and which data should be collected"...

 

[Abdmujib]

oh so sorry about that.

This is the new link "Tables, Virtual Football League Mode 26352, Virtual Football, Soccer"
The data to be collected are Home and Away tables on different sheets.

thanks

 

[Anthony47]

The following macro extract from that page the tables available under the tabs Home matches and Away matches and copy them into the sheets Home and Away:

Sub SeleniumSportradar()
Dim TbColl As Object, tArr, myItm As Object
Dim I As Long, J As Long, myTim As Single
Dim WPage As Object
Dim myUrl As String
Dim Cycle As Long, tabList
'
'CONFIGURATION:
'
myUrl = "https://s5.sir.sportradar.com/bet9javirtuals/en/1/season/2403775/standings"
tabList = Array("tabs-tab-home", "Home", "tabs-tab-away", "Away")                   '<<< 33
'
myTim = Timer
Set WPage = CreateObject("Selenium.WebDriver")
WPage.Start "Chrome", myUrl                         ' <11
''WPage.Start "edge", myUrl                          ' <22
WPage.Get "/"
'
For Cycle = 0 To UBound(tabList) Step 2
    Sheets(tabList(Cycle + 1)).Select
    Range("A:Z").ClearContents                  'Clear the sheet?
    On Error Resume Next
    J = 0
    J = Range("A:T").Find(What:="*", After:=Range("A1"), _
                  SearchOrder:=xlByRows, _
                  SearchDirection:=xlPrevious).Row
    On Error GoTo 0
    J = J + 2
    Debug.Print "AA", WPage.FindElementById(tabList(Cycle)).Attribute("href"), J
'
    If Cycle = 0 Then           'Force Inspect mode
    WPage.Wait 1000
        Application.SendKeys ("^+i")
        WPage.Wait 1500
        Beep
    End If
    WPage.FindElementById(tabList(Cycle)).Click
'
    WPage.Wait 300
    Debug.Print vbCrLf & "Start", "J= " & J, tabList(Cycle), Format(Timer - myTim, "0.00")
    Set TbColl = WPage.FindElementsByTag("table")
    Debug.Print "Tables found: " & TbColl.Count, Format(Timer - myTim, "0.00")
    For I = 1 To TbColl.Count
        Cells(J, 2).Value = "Table #" & I
        tArr = TbColl(I).AsTable.Data
        Cells(J + 1, 1).Resize(UBound(tArr), UBound(tArr, 2)).Value = tArr
        Debug.Print "Table #" & I, UBound(tArr) & " * " & UBound(tArr, 2)
        J = J + UBound(tArr) + 3
    Next I
Next Cycle
'
Debug.Print "END", I, J, Format(Timer - myTim, "0.00")
WPage.Quit
MsgBox ("Collected...")
End Sub

The code uses the highly-deprecated function SendKeys to open the "inspector window" for Chrome, as this was the only situation that allowed me to click the "non clickable" Home-matches and Away-matches pseudo-links. So do not interact with the pc after the Sub SeleniumSportradar has been started until it is completed or stop in error.

The demo file can be downloaded from my dropbox: SeleniumNSportradar.xlsm

 

[Abdmujib]

Thank you Anthony, I kept getting and error message, I think it due to chrome stuff. pls I prefer using Edge. thanks.
in another vain, I think the macro is not running differently like it was the other time, that is call 1 for home sheet and call 2 to run for for away sheet.

I'm so sorry for the troubles.

 

[Anthony47]

Well, thats related to starting Chrome...
You may use Edge, just comment line marked <11 and "un-comment" line marked <22

However Edge gets updated automatically (and I don't know if you can stop that); whenever Edge get updated you probably will need to update the selenium edge driver

 

[kaamho9]

Since you wish to pull two tables you can simply create two "Sub Caller": the difference is that Caller1 will specify Sheets("Sheet1"), and you will manually select Home matches; whereas Caller2 will specify Sheets("Sheet2") and you will manually select Away matches