Cancel merged columns and arrange structure across files in the folders

[Abdo]

Hi,
I would cancel merged columns and cells across all of files are existed in this device"C:\Users\Abdo\Desktop\TYR"
each file contains different counts sheets also I would arrange columns across files from A,C,E,H,M,N,K to A,B,C,D,E,F,G across sheets for each file.
so the macro should be in MASTER file is open , others files are closed .
the result should be for each file is closed , but the macro should in MASTER file
all of files are xls extension .
thanks.
.

 

[Joe4]

Record yourself moving them one at a time.
You will only need to do that once, as once you have it in your code, VBA will do all those steps every time.

 

[Abdo]

how about this try?

Range("A:A,C:C,E:E,H:H,M:M,N:N,K:K").Select
    Range("K1").Activate
    Selection.Copy
    Columns("A:H").Select
    ActiveSheet.Paste

 

[Joe4]

Did you even try it? That code returns errors for me.
It looks to me like you are copying the value from K1 to column A:H.

You originally said:

I would arrange columns across files from A,C,E,H,M,N,K to A,B,C,D,E,F,G across sheets for each file

It looks like you really just want to move column K to the end and delete a bunch of columns.
If so, this should do that:

Sub MyFormattingFixMacro()

    Dim pth As String
    Dim ext As String
    Dim fl As String
    Dim wb As Workbook
    Dim ws As Worksheet

    Application.ScreenUpdating = False

'   Enter path and file extension to look for
    pth = "C:\Users\Abdo\Desktop\TYR\"
    ext = "*.xls*"

'   Target path and extension
    fl = Dir(pth & ext)

'   Loop through each Excel file in folder
    Do While fl <> ""
'       Open workbook and assign to object variable
        Set wb = Workbooks.Open(Filename:=pth & fl)
'       Loop through all sheets
        For Each ws In wb.Worksheets
            With ws
'               Move and delete columns
                .Columns("K:K").Copy .Range("O1")
                .Range("B:B,D:D,F:F,G:G,I:I,J:J,K:K,L:L").Delete Shift:=xlToLeft
            End With
        Next ws
'       Close workbook
        wb.Close SaveChanges:=True
'       Get next file name
        fl = Dir
    Loop
    
    Application.ScreenUpdating = True
    
End Sub