Can I search multiple columns for cells that contain a specific number plus other random text?

[cmstoren]

Hey - I've asked a similar question before except I was looking for a specific word only. A lovely person sent me a code which I can get to work with a specific sequence but can't seem to change it to get results for cells with 11 then any other random text.
The one I've used that works is: =TEXTSPLIT(TEXTJOIN("|",1,IF(Table1[[Class1]:[Class14]]=A1,Table1[Name],"")),";","|")
I've tried to change it to: =TEXTSPLIT(TEXTJOIN("|",1,IF(Table1[[Class1]:[Class14]]="*11*",Table1[Name],"")),";","|") but this just gives me an error. Sadly I don't really understand why the first one works (thank you again for the help!) so am stuck. Is it possible to do what I'm asking?
Last time I was asked to put a sheet on so I hope this is right:

Mr ExcelYear 10 VCE STUDENTS 2025 copy.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U
1	Code	Name	Letter	Number	Class1	Class2	Class3	Class4	Class5	Class6	Class7	Class8	Class9	Class10	Class11	Class12	Class13	Class14	Class15		Year 11 Classes
2		Anna			10EL.1A	10EN.1A	10EVM.2A	10PY.2E	10DR.3B	10ML.3A	10MAB.4A	10ME.4A	10DW.5A	10FFL.5A	10MAA.6E	10SAM.6C	10HG.J	10PE.J	10WB.J		11AC.6A
3		Barbara			10CH.1A	10PY.1G	10CD.2B	10MR.2E	10AVA.3C	10DR.3B	10EN.4E	10LC.4C	10AVB.5E	10DW.5A	11BI.6B		10HG.H	10PE.H	10WB.H		11ART.1A
4		Carrie			11SO.1B		10PL.2B	10RRR.2A	10BI.3A	10EC.3B	10AVA.4A	10IS.4B	10AVB.5F	10LC.5B	10EN.6D	10PY.6C	10HG.D	10PE.D	10WB.D		11ART.4B
5		David			10AVA.1D	10CH.1B	10EC.2D	10RRR.2B	11PY.3C		10AVB.4A	10IS.4A	10EN.5B	10LC.5B	11BI.6B		10HG.E	10PE.E	10WB.E		11BI.1A
6		Eddie			11BI.1A		10PY.2F	10VCD.2C	10FRA.3B	10FRB.3B	10CH.4D	10LC.4C	10AVB.5F	10DW.5A	10AVA.6B	10EN.6D	10HG.A	10PE.A	10WB.A		11BI.3C
7		Falon			10AVB.1D	10CH.1A	10EN.2C	10SAM.2A	10AVA.3C	10YLC.3C	10LC.4C	10OE.4B	11PL.5A		10BI.6E	10PY.6C	10HG.A	10PE.A	10WB.A		11BI.4D
8		Ginny			10MR.1D	10YLC.1A	10EC.2C	10PL.2A	10FRB.3B	10MAA.3B	10BI.4C	10FRA.4A	10EN.5B	10LC.5A	10MAB.6E	10PY.6C	10HG.F	10PE.F	10WB.F		11BI.5E
9		Helen			10AVA.1D	10AVB.1D	10CD.2A	10PY.2F	10BI.3A	10FRA.3B	10FRB.4A	10TB.4B	10CH.5E	10EN.5I	10PH.6A	10SAM.6C	10HG.J	10PE.J	10WB.J		11BI.6B
10		Iris			10EL.1A	10EN.1F	10PY.2E	10SAM.2A	10MAA.3B	10YLC.3C	10BI.4C	10CH.4C	10IEP.5A	10MAB.5D	11DA.6A		10HG.C	10PE.C	10WB.C		11BM.2C
11		Jane			10EN.1A	10MAA.1C	10PL.2B	10VCD.2C	10EC.3B	10MAB.3B	10BI.4C	10ME.4A	10DG.5B	10PY.5B	10TD.6A	10VA.6A	10HG.J	10PE.J	10WB.J		11BM.3B
12		Katie			10EN.1F	10MAA.1C	10EVM.2A	10PY.2E	10MR.3A	10YLC.3C	10OE.4A	10VA.4C	10FFL.5B	10MAB.5D	10SAM.6C	10TB.6A	10HG.B	10PE.B	10WB.B		11BM.6A
13																					11CO.1A
14	263 students																				11CSL.2A
15																					11DA.6A
16																					11DR.6A
17	11BI.6B																				11EAL.1B
18	Barbara	#VALUE!																			11EAL.3A
19	David																				11EC.2B
20																					11EC.3A
All Year 10 students

Cell Formulas
Range	Formula
A18:A19	A18	=TEXTSPLIT(TEXTJOIN("|",1,IF(Table1[[Class1]:[Class14]]=A17,Table1[Name],"")),";","|")
B18	B18	=TEXTSPLIT(TEXTJOIN("|",1,IF(Table1[[Class1]:[Class14]]="*11*",Table1[Name],"")),";","|")
Dynamic array formulas.

Cells with Data Validation
Cell	Allow	Criteria
A17	List	=$U$2:$U$48

 

[Fluff]

How about

=TEXTSPLIT(TEXTJOIN("|",1,IF(ISNUMBER(FIND("11",Table1[[Class1]:[Class14]])),Table1[Name],"")),,"|")

or

=FILTER(Table1[Name],BYROW(Table1[[Class1]:[Class14]],LAMBDA(br,SUM(--(ISNUMBER(FIND("11",br)))))))

 

[cmstoren]

Hey - you are amazing - both of these work!!!! One day I'd love to be able to learn how to do this myself but for now thank you so much - Chloe

 

[Fluff]

You're welcome & thanks for the feedback.