Ayuda Contar Si (dos criterios)

[JavierPeña]

Muy buenas,

Tengo un problema con la fucnión Contar.Si, para dos criterios.

La cosa es que tengo dos columnas:

Columna A (Formato fecha)|Columna B (Formato texto)
01/01/2002|Si
02/05/2002|No
02/05/2002|No
02/05/2002|Si
02/05/2003|No
02/05/2003|Si
02/05/2003|No
02/05/2003|Si


Ahora me gustaría mostar, en otra celda, el número de filas del año 2002 que además son 'Si'.

Cómo podría hacerlo?

Un saludo y muchas gracias!

 

[cgcamal]

Otra opción sin necesidad de crear un rango de criterios sería incluyendo la función FECHA como sigue:

=CONTAR.SI.CONJUNTO(A1:A8,">="&FECHA(2002,1,1),A1:A8,"<="&FECHA(2002,12,31),B1:B8,"Si")

Espero ayude.

Saludos cordiales

 

[cgcamal]

Y una opción más sería multiplicar cada condición y sumarlas matricialmente como sigue:

=SUMA((A1:A8>=VALFECHA("01/01/2002"))*(A1:A8<=VALFECHA("31/12/2002"))*(B1:B8="Si"))

Para que la función trabaje correctamente debés introducirla en cualquier celda, por ejemplo C3 y en
lugar de enviar sólo Enter, debés de enviar Ctrl+Shift+Enter porque es una función matricial que sumará
a través del rango especificado(matriz A1:A8 y B1:B8).

Saludos cordiales

 

[JavierPeña]

muchas gracias por tu ayuda.

La función Contar.Si.conjunto de que versión de excel es?

un saludo

 

[JavierPeña]

y VALFECHA?

 

[JavierPeña]

 

[cgcamal]

CONTAR.SI.CONJUNTO y VALFECHA, aparecieron ambas desde Excel 2007 si no me equivoco.

¿Qué versión de Excel estás usando Javier?

Saludos cordiales

 

[JavierPeña]

2003... es ese el problema?

Has conseguido resultados con esas fórmulas en una hoja de excel sin errores?

 

[cgcamal]

Javier,

2003... es ese el problema?

Justo ése es el problema, estas 2 funciones son más nuevas y Excel 2003 no las reconoce.

Probate con estas 3 opciones, te debería funcionar ahora.

=SUMA((A1:A8>=FECHA(2002,1,1))*(A1:A8<=FECHA(2002,12,31))*(B1:B8="Si"))

o

=CONTAR(A1:A8>=FECHA(2002,1,1),SI(A1:A8<=FECHA(2002,12,31),SI(B1:B8="Si",A1:A8)))

o

=CONTAR(SI(A1:A8>=FECHA(2002,1,1),SI(A1:A8<=FECHA(2002,12,31),SI(B1:B8="Si",A1:A8))))

Las 3 fórmulas son matriciales y debés introducirlas con Ctrl+Shift+Enter.

Espero ayude.

Saludos cordiales

 

[JavierPeña]

ahora si! muchas gracias, me ha funcionado la primera opción pero con la función Fecha separada por ';'

=SUMA((A1:A8>=FECHA(2002;1;1))*(A1:A8<=FECHA(2002;12;31))*(B1:B8="Si"))

gracias otra vez!

 

[MgaNic]

Utiliza la función Año() en una nueva columna para extraer de tu fecha el año
Luego utilizar la función Contar.Si.Conjunto()

Espero te sirva. Saludes y Bendiciones.