ARANDBETWEEN

[Xlambda]

ARANDBETWEEN Returns an array of random integers between 2 numbers, with or without duplicates.

=LAMBDA(va, vb, [r], [c], [uq], [fm],
    LET(
        w, MAX(1, r),
        l, MAX(1, c),
        n, w * l,
        x, FLOOR(MAX(va, vb), 1),
        m, CEILING(MIN(va, vb), 1),
        k, x - m + 1,
        s, SEQUENCE(k, , m),
        IF(
            AND(uq, k < n),
            NA(),
            LET(y, IF(uq, SORTBY(s, RANDARRAY(k)), RANDARRAY(n, , m, x, 1)), z, INDEX(y, SEQUENCE(w, l)), IF(fm = "", z, TEXT(z, fm)))
        )
    )
)

 

[mgirvin]

Whoa!!!!! That is spectacular.

=LAMBDA(n,m,
LET(
z, INDEX(m, 3, ),
x, INDEX(m, 1, ) - NOT(z),
ROUNDUP(RANDARRAY(n, COLUMNS(m)) * (INDEX(m, 2, ) - x) + x, z)
)
)(V13,V14:X16)

And I got my 10 row 3 column rand table : ) : ) : )

Excel Lambda : ) : ) : ) !!!!!

 

[mgirvin]

Whoa!!!!! That is spectacular.

=LAMBDA(n,m,
LET(
z, INDEX(m, 3, ),
x, INDEX(m, 1, ) - NOT(z),
ROUNDUP(RANDARRAY(n, COLUMNS(m)) * (INDEX(m, 2, ) - x) + x, z)
)
)(V13,V14:X16)

And I got my 10 row 3 column rand table : ) : ) : )

Excel Lambda : ) : ) : ) !!!!!

 

[mgirvin]

FREEZE is wild too - with that checked Tools, Formula, Enable iterative calcs : ) : )