AFLAT

[Xlambda]

AFLAT "flattens" any array and filters out blanks, null strings, errors
Other function on minisheet AFLATTEN

=LAMBDA(a,
    LET(r,ROWS(a),c,COLUMNS(a),s,SEQUENCE(r*c),
       q,QUOTIENT(s-1,c)+1,m,MOD(s-1,c)+1,
       x,INDEX(IFERROR(IF(a="","",a),""),q,m),FILTER(x,x<>"")
    )
)

LAMBDA 10.0.xlsx
	A	B	C	D	E	F	G	H	I	J
1	AFLAT function, same functionality as AFLATTEN, only that filters out null strings blanks and errors
2	sample	↓ =""			=AFLATTEN(A3:C5)		=AFLAT(A3:C5)
3	2		#DIV/0!		2		2
4	x	#N/A					x
5	3		y		#DIV/0!		3
6					x		y
7		null string			#N/A
8		blank
9					3
10
11					y
12
AFLAT post

Cell Formulas
Range	Formula
E2,G2	E2	=FORMULATEXT(E3)
C3	C3	=1/0
E3:E11	E3	=AFLATTEN(A3:C5)
G3:G6	G3	=AFLAT(A3:C5)
B2	B2	="↓ "&FORMULATEXT(B3)
B3	B3	=""
B4	B4	=NA()
Dynamic array formulas.

 

[Xlambda]

repeat product names.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1		For fun, added a new "repeat" dimension, horizontally, REDUCE with VSTACK
2
3			rept time
4		prod	vert	horiz
5		TATA	4	3
6		MARUTI	3	2
7		HERO	2	4
8
9		lambda formula
10		=IFNA(DROP(REDUCE(0,SEQUENCE(ROWS(B5:B7)),LAMBDA(v,i,VSTACK(v,IF(SEQUENCE(INDEX(C5:C7,i),INDEX(D5:D7,i)),INDEX(B5:B7,i))))),1),"")
11		TATA	TATA	TATA
12		TATA	TATA	TATA
13		TATA	TATA	TATA
14		TATA	TATA	TATA
15		MARUTI	MARUTI
16		MARUTI	MARUTI
17		MARUTI	MARUTI
18		HERO	HERO	HERO	HERO
19		HERO	HERO	HERO	HERO
20
21		or using REPT
22		=IFNA(DROP(REDUCE(0,SEQUENCE(ROWS(B5:B7)),LAMBDA(v,i,VSTACK(v,REPT(INDEX(B5:B7,i),SEQUENCE(INDEX(C5:C7,i),INDEX(D5:D7,i))^0)))),1),"")
23		TATA	TATA	TATA
24		TATA	TATA	TATA
25		TATA	TATA	TATA
26		TATA	TATA	TATA
27		MARUTI	MARUTI
28		MARUTI	MARUTI
29		MARUTI	MARUTI
30		HERO	HERO	HERO	HERO
31		HERO	HERO	HERO	HERO
32
Sheet4

Cell Formulas
Range	Formula
B10,B22	B10	=FORMULATEXT(B11)
B11:E19	B11	=IFNA(DROP(REDUCE(0,SEQUENCE(ROWS(B5:B7)),LAMBDA(v,i,VSTACK(v,IF(SEQUENCE(INDEX(C5:C7,i),INDEX(D5:D7,i)),INDEX(B5:B7,i))))),1),"")
B23:E31	B23	=IFNA(DROP(REDUCE(0,SEQUENCE(ROWS(B5:B7)),LAMBDA(v,i,VSTACK(v,REPT(INDEX(B5:B7,i),SEQUENCE(INDEX(C5:C7,i),INDEX(D5:D7,i))^0)))),1),"")
Dynamic array formulas.