Adding only academic months to a date

[viktoriacarr]

I am brand new to this thread and am not the most experienced Excel user so maybe I am missing something simple and I would so appreciate anyone's help

I work in the school system with multilanguage learners and when these students come to the USA from another county, we receive federal funding to support them for 33 academic months. I know how to add months to a date so that's no problem but I was wondering if there was any way to add only academic months to a date.

For example, Student A's first day in a US school is 1/4/23 and we are able to claim them for 33 academic months. Is there is a way to add months to a date so I can track when their funding will end while NOT counting the months of June, August, and July to the total number of months?

Thank you in advance for any advice you can give me!! If you need any additional details please let me know

 

[viktoriacarr]

I thought you said that the formula I posted in post#10 worked, but that you needed a formula that works in 2019?

Yes sorry they both work! and I appreciate you helping me with Excel 2019 as well since I need to be able to do it in both 365 and 2019!! I'll mark yours as the solution since you gave that answer to me first

 

[Fluff]

The two formulae give different results for some dates, so which is actually correct?

Fluff.xlsm
	A	B	C
1
2	01/04/2023	01/01/2027	01/12/2026
3	11/12/2023	11/09/2027	11/05/2027
4	30/06/2023	28/02/2027	28/02/2027
Data

Cell Formulas
Range	Formula
B2:B4	B2	=LET(d,EDATE(A2,SEQUENCE(50)),CHOOSEROWS(FILTER(d,(MONTH(d)<6)+(MONTH(d)>8)),33))
C2:C4	C2	=LET(d,EDATE(A2,SEQUENCE(50,,0)),CHOOSEROWS(FILTER(d,(MONTH(d)<6)+(MONTH(d)>8)),33))

 

[Dave Patton]

Thanks for the feedback.
The formulas in B2 and C2 require a recent version of Excel.
I also included a version of Fluff' suggestion for earlier versions of Excel.
N.B. In post #4, you advised that the start month January would be month 1.

If you choose, you can create the Lambda version and use it anywhere in your workbook.
The file does not have to be macro enabled.
The formula in C2 is a Lambda version of the formula in B2. It prompts for the input; "StartD" short for Start Date and "Num_Months" short for Number of Months such as 33 or D1.

With Name Manager, name the Function something appropriate; I named it A_TermEnd and in the Value area put the function information,

Dates Time.xlsm
	A	B	C	D
1	Start	End	# of Months ►	33
2	12-Jul-23	12-Feb-27	12-Feb-27	12-Feb-27
4n

Cell Formulas
Range	Formula
B2	B2	=LET(d,EDATE(A2,SEQUENCE(50,,0)),CHOOSEROWS(FILTER(d,(MONTH(d)<6)+(MONTH(d)>8)),D1))
C2	C2	=A_TermEnd(A2,33)
D2	D2	=AGGREGATE(15,6,EDATE(A2,(ROW($A$1:$A$50)-ROW($A$1)))/((MONTH(EDATE(A2,ROW($A$1:$A$50)-ROW($A$1)))<6)+(MONTH(EDATE(A2,ROW($A$1:$A$50)-ROW($A$1)))>8)),33)

Lambda Functions
Name	Formula
A_TermEnd	=LAMBDA(StartD,Num_Months,LET(d,EDATE(StartD,SEQUENCE(50,,0)),CHOOSEROWS(FILTER(d,(MONTH(d)<6)+(MONTH(d)>8)),Num_Months)))