Add hyperlinks to directories in Word

[brncao]

I have a Word document with lots of directories in it (i.e. C:\abc\def\ghi) and I would like to be able to click on it to take me there.

Is there a macro that will find "C:\*" and convert it as a hyperlink?

1. Find "C:"
2. Highlight text to the right of it including "C:" until it hits a paragraph mark (I assume paragraph mark signals it is the end of the directory path). Just in case, trim any trailing spaces before the paragraph mark before converting it as a hyperlink.
3. Copy selection.
4. Add hyperlink based on selected text.
5. Repeat steps 1-4 throughout the document.

For some reason this forum is removing the backslashes from my post after "C:" but just assume it's there.

 

[Macropod]

Try:

Sub Demo()
Application.ScreenUpdating = False
Dim i As Long
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "C:\\[!^13]{1,}"
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindStop
    .Format = False
    .MatchWildcards = True
    .Execute
  End With
  Do While .Find.Found
    i = i + 1
    .Hyperlinks.Add .Duplicate, .Text, "", , .Text
    .End = .Hyperlinks(1).Range.End
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
End With
Application.ScreenUpdating = True
MsgBox i & " hyperlinks added."
End Sub