Add callout to line graph (last point only)

[smak]

I have a line graph. I want to put a call out on the last point on the chart. I can get it to put a data point (just the % of the point) but not a call out.

what works to get the data point on the graph is below. this macro selects the last point on the graph and adds the data label.

Sub z6_fix_callouts()

 Dim menckPoints As Points
 Dim I As Integer
 Dim NumPoints As Long
     
 '****open tab and chart****
    Sheets("Alaska Epi Curve").Select
    ActiveSheet.ChartObjects("Chart 4").Activate
      
'****select last point on graph****
    Set menckPoints = ActiveChart.FullSeriesCollection(7).Points
        menckPoints(menckPoints.Count).Select
        
'****add data label****
    NumPoints = menckPoints.Count
    ActiveChart.FullSeriesCollection(7).Points(NumPoints).[B][COLOR=rgb(184, 49, 47)]ApplyDataLabels[/COLOR][/B]

End Sub

what would be the syntax for the .ApplyDataLabels portion that would put the call out bubble instead of just a data label

 

[BSALV]

i'd do something with the last answer in this threat

Is there a way to add a callout label to a point in a chart, without using select?

Is there a way to add a callout label to a point in a chart, without using Select? Recording a macro, I got this: Sub Macro9() ActiveSheet.ChartObjects("SPC").Activate ActiveChart.

stackoverflow.com

Sub Macro9()
    ActiveSheet.ChartObjects("SPC").Activate
    ActiveChart.SeriesCollection(1).Points(4).HasDataLabel = True
    ActiveChart.SeriesCollection(1).Points(4).DataLabel.Text = "Point 4 Test"
End Sub

 

[Jon Peltier]

A callout is a data label with some kind of shape, not just a text box. Use bits of this sub to get what you want. Note that you want to remove the default leader lines, which would be redundant, and you have to make the border visible, because when you first change the shape, it has the same border as the textbox, which is none (and this confused me for several minutes).

Sub ChangeDataLabelShape()
  With ActiveChart.SeriesCollection(1)
    .HasLeaderLines = False
    With .Points(1).DataLabel
      .Format.AutoShapeType = msoShapeRectangularCallout
      .Format.Line.Visible = True
    End With
  End With
End Sub