2 range lookups..

[ExcelNewbie2020]

I have this scenario.. i need to lookup a number if its within a range and if its within the range i need to lookup another number if it is also within a range..

for example in cell H5 (4450000) it is within the range in range 1 (from/to)..since it is within the range 2nd step is to check if cell I5 (12) if within range 2 (from/to).which is not so the result is "not ok".
for cells H6 and I6 since they are both within the range the result is "ok"..
for cell H7 outside the range result should be empty cell..

Book1
	A	B	C	D	E	F	G	H	I	J
1	range 1		range 2
2	from	to	from	to
3	4100000	4920999	13	13
4	4100000	4999999	16	20				range 1	range 2	formula here
5	4100000	4999999	31	33				4450000	12	not ok
6								4200000	17	ok
7								5100000	25	empty cell
8
9
10
11
12
13
14
Sheet1

 

[DanteAmor]

Try:

varios 28sep2024.xlsm
	A	B	C	D	E	F	G	H	I	J
1	range 1		range 2
2	from	to	from	to
3	4100000	4920999	13	13
4	4100000	4999999	16	20				range 1	range 2	formula here
5	4100000	4999999	31	33				4450000	12	not ok
6								4200000	17	ok
7								5100000	25	empty cell
Hoja4

Cell Formulas
Range	Formula
J5:J7	J5	=IF(SUMPRODUCT((H5>=$A$3:$A$5)*(H5<=B3:B5)*(I5>=C3:C5)*(I5<=D3:D5)),"ok",IF(OR(SUMPRODUCT((H5>=$A$3:$A$5)*(H5<=B3:B5)),SUMPRODUCT((I5>=C3:C5)*(I5<=D3:D5))),"not ok","empty cell"))

 

[DanteAmor]

I was missing some $
Try:

varios 28sep2024.xlsm
	A	B	C	D	E	F	G	H	I	J
1	range 1		range 2
2	from	to	from	to
3	4100000	4920999	13	13
4	4100000	4999999	16	20				range 1	range 2	formula here
5	4100000	4999999	31	33				4450000	12	not ok
6								4200000	17	ok
7								5100000	25	empty cell
Hoja4

Cell Formulas
Range	Formula
J5:J7	J5	=IF(SUMPRODUCT((H5>=$A$3:$A$5)*(H5<=$B$3:$B$5)*(I5>=$C$3:$C$5)*(I5<=$D$3:$D$5)),"ok",IF(OR(SUMPRODUCT((H5>=$A$3:$A$5)*(H5<=$B$3:$B$5)),SUMPRODUCT((I5>=$C$3:$C$5)*(I5<=$D$3:$D$5))),"not ok","empty cell"))

Or the 365 version:

=LET(a,SUMPRODUCT((H5>=$A$3:$A$5)*(H5<=$B$3:$B$5)),b,SUMPRODUCT((I5>=$C$3:$C$5)*(I5<=$D$3:$D$5)),IF(a*b,"ok",IF(OR(a,b),"not ok","empty cell")))

 

[DanteAmor]

A small change:

=LET(a,SUMPRODUCT((H5>=$A$3:$A$5)*(H5<=$B$3:$B$5)),b,SUMPRODUCT((I5>=$C$3:$C$5)*(I5<=$D$3:$D$5)),IF(a*b,"ok",IF(a+b,"not ok","empty cell")))

 

[DanteAmor]

The sumproduct function is not necessary, and it is only necessary to put the following formula in cell J5:

=LET(a,(A3:A5<=H5:H7)*(B3:B5>=H5:H7),b,(C3:C5<=I5:I7)*(D3:D5>=I5:I7),IF(a*b,"ok",IF(a+b,"not ok","empty cells")))

 

[ExcelNewbie2020]

The sumproduct function is not necessary, and it is only necessary to put the following formula in cell J5:

=LET(a,(A3:A5<=H5:H7)*(B3:B5>=H5:H7),b,(C3:C5<=I5:I7)*(D3:D5>=I5:I7),IF(a*b,"ok",IF(a+b,"not ok","empty cells")))

thanks man, sumproduct works fine..