REPEATBYNUMBER

[smozgur]

REPEATBYNUMBER function takes a range (or table) that has the first column as the item name and the last column as the repeat number then returns a new column of rows with the item names repeated by the required number of times. (I learned the main idea from Karina Adcock, and used the TAKE function to make it work with a single range/table parameter).

EDIT: This function assumes that each product in the source data exists in the inventory (Repeat >= 1). For an alternative implementation that considers Repeat = 0 please see @Xlambda's RPTBYNR function below.

=LAMBDA(data,
    XLOOKUP(
        SEQUENCE(SUM(TAKE(data,,-1))),
        VSTACK(1, SCAN(1,TAKE(data,,-1),LAMBDA(a,b,a+b))),
        VSTACK(TAKE(data,,1),""),
        ,
        -1
    )
)

RepeatByNumber
	A	B	C	D	E	F
1	Product	Repeat		Result (range param)		Result (table param)
2	Apple	5		Apple		Apple
3	Banana	4		Apple		Apple
4	Cherry	2		Apple		Apple
5	Strawberry	4		Apple		Apple
6				Apple		Apple
7				Banana		Banana
8				Banana		Banana
9				Banana		Banana
10				Banana		Banana
11				Cherry		Cherry
12				Cherry		Cherry
13				Strawberry		Strawberry
14				Strawberry		Strawberry
15				Strawberry		Strawberry
16				Strawberry		Strawberry
Sheet4

Cell Formulas
Range	Formula
D2:D16	D2	=REPEATBYNUMBER(A2:B5)
F2:F16	F2	=REPEATBYNUMBER(ProductTable)
Dynamic array formulas.

 

[Dave Patton]

Thanks for the information.
I am signed in for Beta 365 Insider but the updates have not arrived for months or years.
I just try to help people with basic Excel. Good luck with Python and other sophisticated tools. Dave

 

[Xlambda]

Here are 2 Xmas trees for you guys, one to always remember that numbers can be +, -, 0 and one that uses offset letters as ornament, to remember the questions never answered.
function here: AXMAS

Book1.xlsx
	A	B	C	D	E	F	G
1
2		⭐	⭐			⭐	⭐
3		‖	‖			‖	‖
4		0	-			o	s
5		-0	-0			of	so
6		--0	--+			sff	tos
7		-00+	+-+-			tseo	otfs
8		0+00-	---++			ffess	sssss
9		0+----	00--+0			tsfffo	ofesot
10		+-0+-0+	+0+-0+-			efsesot	seoessf
11		-0--00-+	0-+0+-0+			oseottfs	sfoefeto
12		-00-+-+++	++-000---			ttsfofoff	otteefsso
13		-++++-0-++	------0-00			tstetotote	foeeossfto
14		-000+00-0++	-0-0-+0-+++			tffeeeefsfe	estostttees
15		-0----0-+0+0	0-00-0-00+-0			eotoefefetef	esooseofefeo
16		++-0++0+--+-+	+-+-0-+0+-+0+			ttstftetefftf	eotsfsfteoste
17		0--+0--0+0++-+	+++0-++0++0++0			otfoesoefeostt	ofsteseffsttot
18		00-00-+0+++0+--	+-0+0-0+0+00-0+			tefsttesoftfoss	sfftetsofffsfst
19		-+0++0+--++--0+-	--00-+-00+0-+0++			teotososftsotose	otfeostootsstoss
20		0+++000++-0++0+0+	0++-00+0++0+00+-0			tessossofototfsso	stsftssfossfostos
21		+--0000+--++--0++-	++0-0+-0-0++0+++-0			offfseftetosotftfe	tosefsotttseoesooo
22		0++-+--0+-0-0++0+-0	00-+-+0-++-+00+0-0+			sfoeeeststttssteeof	ftofofftfottfstseot
23		-0-0-++000-+000-0000	+0+++0-00-++-0++0-+0			ofeefofeeefeftottoto	oststsetsttetstssosf
24		0+---0---++++-+0++0-0	-0+0-0+-00+00+-++++-0			tooefsfoooooeooffefet	teeseseoessteefffteeo
25		0---++-+++---00+++-0-0	--0++--0-0-+0-00---+++			osfosstfstfttftefeeseo	tffetofeteseestfseofst
26		000+-+-+-0-++000---+++0	000+-+0-+00+0++-+----0-			sttoeessfeotstssftsfees	seesefstosofstfstseefee
27		🎁▓	▓🎁			🎁▓	▓🎁
28
Sheet1

Cell Formulas
Range	Formula
B2:C27	B2	=AXMAS(23,{"-";"+";"0"})
F2:G27	F2	=AXMAS(23,{"o";"f";"s";"e";"t"})
Dynamic array formulas.

 

[lrobbo314]

That's really cool XLAMBDA. I really dig your contributions to this forum.

 

[Cubist]

Not sure if this thread is strictly for lambda functions only but a solution with no lambda.

Book1
	A	B	C	D
1	Product	Repeat
2	Apple	5		Apple
3	Banana	3		Apple
4	Cherry	2		Apple
5	Strawberry	1		Apple
6				Apple
7				Banana
8				Banana
9				Banana
10				Cherry
11				Cherry
12				Strawberry
Sheet3

Cell Formulas
Range	Formula
D2:D12	D2	=TOCOL(IFS(B2:B5>=SEQUENCE(,MAX(B2:B5)),A2:A5),2)
Dynamic array formulas.

 

[LogChief]

You're absolutely right, this is a great solution, and I believe it's one that's been explored in this forum already. You will still need a lambda to turn it into a custom function in your name manager.

 

[smozgur]

Not sure if this thread is strictly for lambda functions only but a solution with no lambda.

Yes, this thread and the forum - "Excel LAMBDA Functions" is strictly for lambda functions.

 

[Cubist]

You're absolutely right, this is a great solution, and I believe it's one that's been explored in this forum already. You will still need a lambda to turn it into a custom function in your name manager.

I missed that. Thanks.