Sound With Message Box

[Guzzlr]

Sub Delete_Column()

With Worksheets("Sheet1")
    If Range("D1") <> "Percentage" Then
        MsgBox "Please Run Program First"
        Exit Sub
        Else: Columns("D:D").Delete
    End If
End With


End Sub

Hello All...
Quick Question:
How do I get sound, when the Message Box is displayed?
Thanks for the help
excel 2010

 

[Tetra201]

You can use

MsgBox "Please Run Program First", vbCritical

or

MsgBox "Please Run Program First", vbExclamation

to get one of the system sounds.

 

[Logit]

Option Explicit


Private Declare Function sndPlaySound32 Lib "winmm.dll" _
Alias "sndPlaySoundA" (ByVal lpszSoundName _
As String, ByVal uFlags As Long) As Long


Sub Delete_Column()
    Dim PlaySound As Boolean


With Worksheets("Sheet1")
    If Range("D1") <> "Percentage" Then
        MsgBox "Please Run Program First"
        Exit Sub
        Else: Columns("D:D").Delete
        Call sndPlaySound32("C:\windows\media\chord.wav", 1)


    End If
End With




End Sub

 

[Guzzlr]

I like the vbExclamation better...Thanks for the help

 

[Tetra201]

You are welcome.

 

[mikerickson]

Neither vbCritical nor vbExclamation work on my Mac, I have to use the work-around

Beep
MsgBox "Please Run the program"

 

[ColdGeorge]

Hi Guzzlr

I hope this works for you

With Worksheets("Sheet1")
    If Range("D1") <> "Percentage" Then
        Application.Speech.Speak "Please Run Program First"
        Exit Sub
        Else: Columns("D:D").Delete
    End If
End With

ColdGeorge

 

[ColdGeorge]

Hi all

This one is even a little better

With Worksheets("Sheet1")
    If Range("D1") <> "Percentage" Then
        MsgBox "Please Run Program First"
        Application.Speech.Speak "Please Run Program First"
        Exit Sub
        Else: Columns("D:D").Delete
    End If
End With

ColdGeorge

 

[Guzzlr]

With Worksheets("Sheet1")
    If Range("D1") <> "Percentage" Then
        MsgBox "Please Run Program First"
        Application.Speech.Speak "Please Run Program First"
        Exit Sub
        Else: Columns("D:D").Delete
    End If
End With

This is interesting, an actual voice. The problem is the voice happens after the msg box is closed, after OK is selected. It would be cool to have the voice happen the same time the msgbox is displayed.
Thanks

 

[Jaafar Tribak]

It would be cool to have the voice happen the same time the msgbox is displayed.

Try this :

Option Explicit

#If VBA7 Then
    Private Declare PtrSafe Function SetTimer Lib "user32" (ByVal hwnd As LongPtr, ByVal nIDEvent As LongPtr, ByVal uElapse As Long, ByVal lpTimerFunc As LongPtr) As LongPtr
    Private Declare PtrSafe Function KillTimer Lib "user32" (ByVal hwnd As LongPtr, ByVal nIDEvent As LongPtr) As Long
#Else
    Private Declare Function SetTimer Lib "user32" (ByVal hwnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerFunc As Long) As Long
    Private Declare Function KillTimer Lib "user32" (ByVal hwnd As Long, ByVal nIDEvent As Long) As Long
#End If


Sub Delete_Column()
    With Worksheets("Sheet1")
        If Range("D1") <> "Percentage" Then
            SetTimer Application.hwnd, 0, 100, AddressOf VoiceMessage
            MsgBox "Please Run Program First"
            Exit Sub
            Else: Columns("D:D").Delete
        End If
    End With
End Sub


Sub VoiceMessage()
    KillTimer Application.hwnd, 0
    Application.Speech.Speak "Please Run Program First"
End Sub