Greater than or equal to symbol in vba string msgbox

[Huhenyo]

All, I've been doing quite a few searches and I can't seem to find out how to put a ≥ symbol into a msgbox. I can find all sorts of threads on putting it into a cell, but chrW($H2265) doesn't work in a vba string. For instance this code:

msgbox chrW(&H2265)

just outputs =. Have any of you been able to put a ≥ into a vba string for output to the user in a message box?

Thank you for your help!

 

[Jaafar Tribak]

The VBA standard Msgbox is in fact a wrapper for the MessageBoxA API function and as such, it converts all strings that are passed in its arguments from Unicode to Ansi that's why the ≥ caracter is not displayed

In order to avoid this unwanted string conversion, we should pass the String Pointer of the unicode character (instead of passing the actual character) to an Alias of the MessageBox API

The MyMsgBox Function below is actually a wrapper for the API Alias ... I kept the prototype definition of the MyMsgBox function in line with the standard VBA Msgbox for easy use ( except the optional HelpFile and Context arguments)

Example:

Option Explicit

#If VBA7 Then
     Declare PtrSafe Function MyMsgBoxAlias Lib "user32" Alias "MessageBoxW" (ByVal hwnd As LongPtr, ByVal lpText As LongPtr, Optional ByVal lpCaption As LongPtr, Optional ByVal wType As Long = 0) As Long
#Else
     Declare Function MyMsgBoxAlias Lib "user32" Alias "MessageBoxW" (ByVal hwnd As Long, ByVal lpText As Long, ByVal lpCaption As Long, ByVal wType As Long) As Long
#End If


Function MyMsgBox(ByVal Prompt As String, Optional ByVal Buttons As VbMsgBoxStyle, Optional ByVal Title As String = vbNullChar) As VbMsgBoxResult
    MyMsgBox = MyMsgBoxAlias(0, StrPtr(Prompt), StrPtr(Title), Buttons)
End Function


Sub Test()
    Dim s As String
    s = ChrW(&H2265)
    MyMsgBox s, , "Test"
End Sub

 

[Ron Coderre]

The messagebox is a Windows feature that is shared by all Windows applications. Consequently, you would change the font by editing the Windows appearance settings. However, be aware that the changed font will apply to all message boxes in all Windows applications on the PC you change.

An Excel alternative would be to create a custom userform and change the font on the object that displays the message.

Is that something you can work with?

 

[jtakw]

Hi,

I'm probably misunderstanding the question:

Sub test()
    MsgBox prompt:=">=", Title:=">="
End Sub

would put the Greater than or Equal in the message box.

This may also help: http://dailydoseofexcel.com/archives/2010/11/19/unicode-and-vbas-chrw-and-ascw-functions/