Simple Macro to cut and paste based on cell value

[norts55]

Can anyone share a simple macro that will cut and paste an entire row from one worksheet to another based on part of a cell value within one cell in a certain column? Below I kind of a step by step...

Search Column "C" on worksheet "All" for the word "Time".
Select all (entire) rows that have the word "Time" in column "C"
Cut those selected rows and paste to the top of the worksheet "All Time" - (This worksheet will be empty until the paste occurs)<o></o>

 

[VoG]

Try

Sub atest()
Dim LR As Long, i As Long
With Sheets("Time")
    LR = .Range("C" & Rows.Count).End(xlUp).Row
    For i = 1 To LR
        With .Range("C" & i)
            If .Value = "Time" Then .EntireRow.Cut Destination:=Sheets("All Time").Range("A" & Rows.Count).End(xlUp).Offset(1)
        End With
    Next i
End With
End Sub

 

[Titian]

Perhaps

With Sheets("Time")

should be

With Sheets("All")

 

[norts55]

Thanks for your help this is greatly appreciated.<o></o>
<o> </o>
Ok, this works great except for one thing. I need the search and select to find cells that contain the word "Time" not equal to "Time". Is that possible?<o></o>

 

[VoG]

Thanks for the correction Titian

Try this for contains Time

Sub atest()
Dim LR As Long, i As Long
With Sheets("All")
    LR = .Range("C" & Rows.Count).End(xlUp).Row
    For i = 1 To LR
        With .Range("C" & i)
            If .Value Like "*Time*" Then .EntireRow.Cut Destination:=Sheets("All Time").Range("A" & Rows.Count).End(xlUp).Offset(1)
        End With
    Next i
End With
End Sub

 

[norts55]

Again thank you for your help with this. The Macro is working however it is only selecting the first row that contains the word time. I need it to find all rows that contain the word time, then copy and paste all of those. Is that possible?

 

[VoG]

Is column A empty?

 

[norts55]

Where the paste is occuring (sheet all time), yes. Not on the sheet where the selection is happening.

 

[VoG]

Try

Sub atest()
Dim LR As Long, i As Long
With Sheets("All")
    LR = .Range("C" & Rows.Count).End(xlUp).Row
    For i = 1 To LR
        With .Range("C" & i)
            If .Value Like "*Time*" Then .EntireRow.Cut Destination:=Sheets("All Time").Range("C" & Rows.Count).End(xlUp).Offset(1, -2)
        End With
    Next i
End With
End Sub

 

[norts55]

That works. Thank You!