Detect Mouse Movement

[JohnPoole]

Hi all, I was wondering if anybody knows how to detect to see if the mouse has moved? I'm not sure if this possible, or indeed exactly how sensitive it would need to be, so I guess any solution would need to be able to determine how many pixels the position has changed before executing further code.

Any advice appreciated as always.

 

[Tom Urtis]

Depends on how you want to detect the mouse movement.

If you are interested in seeing the coordinates in a cell on a constant basis such as in cell A1, run the macro named PositionXY and move the mouse around.

To exit the procedure, double click any cell and then either hit Esc, Enter, or select any cell.

All this goes into a new fresh standard module:

Public Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
Public Type POINTAPI
x As Long
y As Long
End Type
 
Sub PositionXY()
Dim lngCurPos As POINTAPI
Do
GetCursorPos lngCurPos
Range("A1").Value = "X: " & lngCurPos.x & " Y: " & lngCurPos.y
DoEvents
Loop
End Sub

 

[MorganO]

Yes, you can detect mouse movement in Excel VBA. I've attached code to give you an idea of how it can work:

Private Type POINTAPI
    X As Long
    Y As Long
End Type
Private Declare Function GetDeviceCaps Lib "gdi32" (ByVal hdc As Long, ByVal nIndex As Long) As Long
Private Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
Private Declare Function GetDC Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function ReleaseDC Lib "user32" (ByVal hwnd As Long, ByVal hdc As Long) As Long
 
Sub MouseMoveTest()
    Dim lngCurPos As POINTAPI
    Dim DocZero As POINTAPI
    Dim PointsPerPixelY As Double
    Dim PointsPerPixelX As Double
    Dim hdc As Long
 
    hdc = GetDC(0)
    PointsPerPixelY = 72 / GetDeviceCaps(hdc, 90)
    PointsPerPixelX = 72 / GetDeviceCaps(hdc, 88)
    ReleaseDC 0, hdc
 
    DocZero.Y = ActiveWindow.PointsToScreenPixelsY(0)
    DocZero.X = ActiveWindow.PointsToScreenPixelsX(0)
 
    Do
 
        GetCursorPos lngCurPos
 
        Rowposition = (lngCurPos.Y - DocZero.Y) * PointsPerPixelY
        Colposition = (lngCurPos.X - DocZero.X) * PointsPerPixelX
 
        Cells(1, 1) = Rowposition 
        Cells(1, 2) = Colposition 
 
    DoEvents
 
    Loop
End Sub

Put this code in any sheet and run it. When you move the mouse you will see the values in cells A1 and B1 change. These number correspond to the cursor position relative to the worksheet, not the computer screen. You should be able to easily modify this to your needs.

Take care.

Owen

 

[JohnPoole]

Great, I'll give those a go, thx for the help guys.