Issue with a line of code - "Object doesn't support this property or method"

Sharid · May 27, 2019

Hi

Could somebody please help me,

The following code is should navigate to google and then pull all the urls from the link to a sheet. I keep having issues with the line of code shown in red. "Object doesn't support this property or method"

Code:

Sub webpage()

    Dim internet As Object
    Dim internetdata As Object
    Dim div_result As Object
    Dim header_links As Object
    Dim link As Object
    Dim URL As String

    Set internet = CreateObject("InternetExplorer.Application")
    internet.Visible = True

    URL = "https://www.google.co.in/search?q[COLOR=#000000]=how+to+program+in+vba"[/COLOR]
    internet.Navigate URL

    Do Until internet.ReadyState >= 4
        DoEvents
    Loop

    Application.Wait Now + TimeSerial(0, 0, 5)

    Set internetdata = internet.Document
    Set div_result = internetdata.getElementById("res")


    Set header_links = div_result.getElementsByTagName("h3")

    For Each h In header_links
        Set link = h.ChildNodes.Item(0)
        'Cells(Range("A" & Rows.Count).End(xlUp).Row + 1, 1) = link.href
        Set internetdata = internet.Document
        Set internetdatalink = internetdata.getElementById("rso")
        Set internetlink = internetdatalink.getElementsByTagName("h3")
        For Each texttext In internetlink
       [COLOR=#ff0000] ActiveSheet.Cells(i, 2).Value = texttext.href[/COLOR]
        i = i + 1
        Next texttext
    Next

    MsgBox "done"
End Sub

Thanks for having a look

Domenic · May 28, 2019

With regards to your macro...

Code:

1) You should declare all your variables.

2) Your code creates 2 different instances of InternetExplorer.  So you should remove one of them.


3) You should check the Busy property of the InternetExplorer object, in addition to the ReadyState property.


4) You should check whether there's another page available to go to before clicking the next page element.  If no other page is available, you can exit the Do/Loop.


5) It's probably a good idea to pause the macro again for a few seconds after going to the next page and checking the Busy and ReadyState properties.

Accordingly, your macro can be amended as follows...

Code:

Sub webpage()

    Dim ie As Object
    Dim htmlDoc As Object
    Dim nextPageElement As Object
    Dim div As Object
    Dim link As Object
    Dim url As String
    Dim pageNumber As Long
    Dim i As Long
    
    url = "https://www.google.co.uk/search?q=" & Replace(Worksheets("Sheet1").Range("A1").Value, " ", "+")


    Set ie = CreateObject("InternetExplorer.Application")
    
    With ie
        .Visible = True
        .navigate url
        Do While .Busy Or .readyState <> 4
            DoEvents
        Loop
    End With


    Application.Wait Now + TimeSerial(0, 0, 5)
    
    Set htmlDoc = ie.document


    pageNumber = 1
    i = 2
    Do
        For Each div In htmlDoc.getElementsByTagName("div")
            If div.getAttribute("class") = "r" Then
                Set link = div.getElementsByTagName("a")(0)
                Cells(i, 2).Value = link.getAttribute("href")
                i = i + 1
            End If
        Next div
        If pageNumber >= 6 Then Exit Do 'the first 6 pages
        Set nextPageElement = htmlDoc.getElementById("pnnext")
        If nextPageElement Is Nothing Then Exit Do
        nextPageElement.Click 'next web page
        Do While ie.Busy Or ie.readyState <> 4
            DoEvents
        Loop
        Application.Wait Now + TimeSerial(0, 0, 5)
        Set htmlDoc = ie.document
        pageNumber = pageNumber + 1
    Loop


    MsgBox "done"
    
    Set ie = Nothing
    Set htmlDoc = Nothing
    Set nextPageElement = Nothing
    Set div = Nothing
    Set link = Nothing


End Sub

Sharid · May 28, 2019

Domenic

This is absolutely awesome, there was no way I was going to get this far without your kind help.

A very big Thank you,

You are a god amongst us mortals

Domenic · May 28, 2019

That's great, I'm glad I could help. And thank you for your kind words. Cheers!

Issue with a line of code - "Object doesn't support this property or method"

Sharid

Well-known Member

Domenic

MrExcel MVP

Excel Facts

Sharid

Well-known Member

Domenic

MrExcel MVP

Similar threads

Forum statistics

Share this page

Issue with a line of code - "Object doesn't support this property or method"

Sharid

Well-known Member

Domenic

MrExcel MVP

Excel Facts

Sharid

Well-known Member

Domenic

MrExcel MVP

Similar threads

Forum statistics

Share this page

We've detected that you are using an adblocker.

Which adblocker are you using?

Disable AdBlock

Disable AdBlock Plus

Disable uBlock Origin

Disable uBlock