Retrieving specific numbers from a decimal number

[Eggplant2016]

I have 4 cells that contribute to a total number.
Cells G24, N24, G32, N32. These cells currently sum a range of numbers from the 5 cells above them respectively.
The total number that these 4 cells add up to can be anywhere from an example number such as "1205.25" to something basic like "50"

Cells AJ6:AR6 are individual cells with AJ6 representing the hundred thousands all the way down to AR6 which represents the hundredths.

I need cell AR6 to take the sum of cells G24, N24, G32, N32 and only take the "hundredths" number. AQ6 will do the same but only take the tenths, AP6 will do the same and only take the ones, etc all the way to AJ6.

Is this possible??

Thank you so much for the help!

 

[Scott Huish]

Re: Retrieving specific numbers from a decimaled number

I think this is what you want:

=IFERROR(MID(SUM(SUBSTITUTE(SUM($G24,$G32,$N24,$N32),".","")),COLUMNS($A$1:A1)-COLUMN($A$1)+1,1)+0,"")

Copy across.

Excel 2010
	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W	X	Y	Z	AA	AB	AC	AD	AE	AF	AG	AH	AI	AJ	AK	AL	AM	AN	AO	AP	AQ	AR
23
24	1202.25							1																						1	2	0	5	2	5
25
26
27
28
29
30
31
32	1							1
Sheet1

Cell Formulas
Range	Formula
AJ24	=IFERROR(MID(SUM(SUBSTITUTE(SUM($G24,$G32,$N24,$N32),".","")),COLUMNS($A$1:A1)-COLUMN($A$1)+1,1)+0,"")
AK24	=IFERROR(MID(SUM(SUBSTITUTE(SUM($G24,$G32,$N24,$N32),".","")),COLUMNS($A$1:B1)-COLUMN($A$1)+1,1)+0,"")
AL24	=IFERROR(MID(SUM(SUBSTITUTE(SUM($G24,$G32,$N24,$N32),".","")),COLUMNS($A$1:C1)-COLUMN($A$1)+1,1)+0,"")
AM24	=IFERROR(MID(SUM(SUBSTITUTE(SUM($G24,$G32,$N24,$N32),".","")),COLUMNS($A$1:D1)-COLUMN($A$1)+1,1)+0,"")
AN24	=IFERROR(MID(SUM(SUBSTITUTE(SUM($G24,$G32,$N24,$N32),".","")),COLUMNS($A$1:E1)-COLUMN($A$1)+1,1)+0,"")
AO24	=IFERROR(MID(SUM(SUBSTITUTE(SUM($G24,$G32,$N24,$N32),".","")),COLUMNS($A$1:F1)-COLUMN($A$1)+1,1)+0,"")
AP24	=IFERROR(MID(SUM(SUBSTITUTE(SUM($G24,$G32,$N24,$N32),".","")),COLUMNS($A$1:G1)-COLUMN($A$1)+1,1)+0,"")
AQ24	=IFERROR(MID(SUM(SUBSTITUTE(SUM($G24,$G32,$N24,$N32),".","")),COLUMNS($A$1:H1)-COLUMN($A$1)+1,1)+0,"")
AR24	=IFERROR(MID(SUM(SUBSTITUTE(SUM($G24,$G32,$N24,$N32),".","")),COLUMNS($A$1:I1)-COLUMN($A$1)+1,1)+0,"")

 

[Eggplant2016]

Re: Retrieving specific numbers from a decimaled number

It seems that what is happening is that when the number is not large enough, i.e "125,000.25" , then it is not populating the correct cells with the correct numbers.


For example if the sum of G24+N24+G32+N32= 12.50, I would like the cells to show this:

AJ6 AK6 AL6 AM6 AN6 AO6 AP6 AQ6 AR6
0 0 0 0 0 1 2 5 0

But if the sum of G24+N24+32+N32=12500.50, I would like the cells to show this:

AJ6 AK6 AL6 AM6 AN6 AO6 AP6 AQ6 AR6
0 0 1 2 5 0 0 5 0

Thanks for helping! Sorry if I didn't explain properly the first time

 

[Scott Huish]

Re: Retrieving specific numbers from a decimaled number

In AJ24:
=MID(TEXT(SUBSTITUTE(TEXT(SUM($G24,$G32,$N24,$N32),"0.00"),".",""),"000000000"),COLUMNS($A$1:A1)-COLUMN($A$1)+1,1)

Copy across.

Excel 2010
	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W	X	Y	Z	AA	AB	AC	AD	AE	AF	AG	AH	AI	AJ	AK	AL	AM	AN	AO	AP	AQ	AR
24	9.5							1																						0	0	0	0	0	1	2	5	0
25
26
27
28
29
30
31
32	1							1
33
Sheet1

Cell Formulas
Range	Formula
AJ24	=MID(TEXT(SUBSTITUTE(TEXT(SUM($G24,$G32,$N24,$N32),"0.00"),".",""),"000000000"),COLUMNS($A$1:A1)-COLUMN($A$1)+1,1)
AK24	=MID(TEXT(SUBSTITUTE(TEXT(SUM($G24,$G32,$N24,$N32),"0.00"),".",""),"000000000"),COLUMNS($A$1:B1)-COLUMN($A$1)+1,1)
AL24	=MID(TEXT(SUBSTITUTE(TEXT(SUM($G24,$G32,$N24,$N32),"0.00"),".",""),"000000000"),COLUMNS($A$1:C1)-COLUMN($A$1)+1,1)
AM24	=MID(TEXT(SUBSTITUTE(TEXT(SUM($G24,$G32,$N24,$N32),"0.00"),".",""),"000000000"),COLUMNS($A$1:D1)-COLUMN($A$1)+1,1)
AN24	=MID(TEXT(SUBSTITUTE(TEXT(SUM($G24,$G32,$N24,$N32),"0.00"),".",""),"000000000"),COLUMNS($A$1:E1)-COLUMN($A$1)+1,1)
AO24	=MID(TEXT(SUBSTITUTE(TEXT(SUM($G24,$G32,$N24,$N32),"0.00"),".",""),"000000000"),COLUMNS($A$1:F1)-COLUMN($A$1)+1,1)
AP24	=MID(TEXT(SUBSTITUTE(TEXT(SUM($G24,$G32,$N24,$N32),"0.00"),".",""),"000000000"),COLUMNS($A$1:G1)-COLUMN($A$1)+1,1)
AQ24	=MID(TEXT(SUBSTITUTE(TEXT(SUM($G24,$G32,$N24,$N32),"0.00"),".",""),"000000000"),COLUMNS($A$1:H1)-COLUMN($A$1)+1,1)
AR24	=MID(TEXT(SUBSTITUTE(TEXT(SUM($G24,$G32,$N24,$N32),"0.00"),".",""),"000000000"),COLUMNS($A$1:I1)-COLUMN($A$1)+1,1)

 

[Eric W]

Re: Retrieving specific numbers from a decimaled number

Another option:

=MOD(INT(($G24+$G32+$N24+$N32)/10^(7-COLUMNS($AJ24:AJ24))),10)

Put in AJ24 and drag to the right.

 

[Eggplant2016]

Re: Retrieving specific numbers from a decimaled number

Eric- That's perfect, thanks!

 

[Eric W]

Re: Retrieving specific numbers from a decimaled number

Glad we could help.