Help converting code - time remaining function

[Dr. Demento]

Evening all.

I found some code that, at least from the basic description, does what I would like. However, it's written in a variety of C. It's not too long; would anyone be willing to "translate" it?

The end goal is a Function that can be called (additional input: execute at x% of total --> first part of program would test if the x% of total loops have been performed, function would be executed; otherwise Exit) and will output the time remaining and the percent complete.

https://www.codeproject.com/Articles/27436/Remaining-Timer

Any takers?

 

[Dr. Demento]

One thing I forgot. Currently, I'm trying to implement this in Outlook, so if it's application "universal," that would be awesome!! Obviously, it has a lot of potential in Excel as well.

Thanks y'all.

 

[shg]

Maybe this will get you started. Look at the status bar.

Sub demento()
  Dim i As Long
  
  Application.StatusBar = "ETC: " & ETC ' initialize
  
  For i = 1 To 5
    Application.Wait Now + (5 + 3 * Rnd) / 86400
    Application.StatusBar = "ETC: " & Format(ETC(i / 5), "hh:mm:ss")
    DoEvents
  Next i
  
  Application.StatusBar = False
  Beep
End Sub

Function ETC(Optional dPctComp As Double = 0#) As Variant
  ' Returns estimated time to complete based on start time and percent complete
  
  Static tBeg       As Date

  Select Case dPctComp
    Case 0#
      tBeg = Now
      ETC = "Starting now ..."
    Case Is < 0#, Is > 1#
      ETC = "Invalid percent complete!"
    Case Else
      ETC = (Now - tBeg) * (1# / dPctComp - 1#)
  End Select
End Function

 

[Dr. Demento]

Much appreciated, shg. I don't know if it was because it's Monday or what, but it took me a while to suss out what each variable in the slope equation paired to. I got it now!! Thank you!!

Out of curiosity, why did you subtract one from the slope (1# / dPctComp - 1#)?

 

[shg]

You're welcome.

why did you subtract one from the slope (1# / dPctComp - 1#)?

(1# / dPctComp - 1#) is not the slope; it's how many more multiples of the elapsed time you need to complete. If you're 1/3 done, you need twice as much time to finish as you have spent so far.