VBA to dial a phone number through a connected modem

[kelly mort]

Hello All,
This idea just came to me and I wanna verify if it holds. I wanna dial a phone line through a connected modem by a VBA code. If this is possible please let me know.
Thanks
Kelly

 

[shg]

Wow, that's an oldie.

Option Explicit

' from http://support.microsoft.com/kb/141625

Declare Function tapiRequestMakeCall Lib "tapi32.dll" _
                                     (ByVal stNumber As String, ByVal stDummy1 As String, _
                                      ByVal stDummy2 As String, ByVal stDummy3 As String) As Long
Public Const ID_CANCEL = 2
Public Const MB_OKCANCEL = 1
Public Const MB_ICONSTOP = 16, MB_ICONINFORMATION = 64


' ***********************************************************
' FUNCTION: DialNumber()
'
' PURPOSE: To dial a telephone number using the computer's modem
'
' ARGUMENTS:
'    PhoneNumber: The telephone number to dial
'
' EXAMPLE:
'    Type the following in the Debug window to dial a phone number:
'
'       ? DialNumber("555-1212")
' ***********************************************************
Function DialNumber(PhoneNumber)
  Dim Msg As String
  Dim MsgBoxType As Integer
  Dim MsgBoxTitle As String
  Dim RetVal        As Long

  ' Ask the user to pick up the phone.
  Msg = "Please pickup the phone and click OK to dial " _
        & PhoneNumber
  MsgBoxType = MB_ICONINFORMATION + MB_OKCANCEL
  MsgBoxTitle = "Dial Number"

  If MsgBox(Msg, MsgBoxType, MsgBoxTitle) = ID_CANCEL Then
    Exit Function
  End If

  ' Send the telephone number to the modem.
  RetVal = tapiRequestMakeCall(PhoneNumber, "", "", "")

  If RetVal < 0 Then
    Msg = "Unable to dial number " & PhoneNumber
    GoTo Err_DialNumber
  End If

  Exit Function

Err_DialNumber:    'This is not an On Error routine.
  Msg = Msg & vbCr & vbCr & _
        "Make sure no other devices are using the Com port"
  MsgBoxType = MB_ICONSTOP
  MsgBoxTitle = "Dial Number Error"
  MsgBox Msg, MsgBoxType, MsgBoxTitle
End Function

 

[kelly mort]

Hello shg,
I have a compile error from the below and I am asked to update it for 64 bit use.

Declare Function tapiRequestMakeCall Lib "tapi32.dll" _
                                     (ByVal stNumber As String, ByVal stDummy1 As String, _
                                      ByVal stDummy2 As String, ByVal stDummy3 As String) As Long

 

[shg]

https://www.mrexcel.com/forum/excel-questions/70207-can-excel-dial-phone-numbers.html

 

[kelly mort]

The dialer shows but when I dial it just hangs up. Says I should lift the receiver and click to talk then shows "call failed: there was no answer"

 

[shg]

I've not used it since I last had a modem, which was two computers ago, so no suggestion, sorry.

 

[kelly mort]

Oh okay thanks