You've entered too many arguments for this function

[kae2011]

My current formula is
=IF(D$14>EOMONTH($C15,0)-$C15+1,"NA",
IF(OR(DATE(YEAR($C15),MONTH($C15),D$14)<I_ER_START, DATE(YEAR($C15),MONTH($C15),D$14)>I_ER_END),"NA",
IF(OR(DATE(YEAR($C15),MONTH($C15),D$14)<C_EMP_START, DATE(YEAR($C15),MONTH($C15),D$14)>C_EMP_END),"NE",
IFERROR(
@INDEX(T_VAC[Vacation Type],SUMPRODUCT(--(T_VAC[Employee]=I_ER_EMP),--(T_VAC[Start Date]=DATE(YEAR($C15),MONTH($C15),D$14)),ROW(T_VAC[Vacation Type]))-@ROW(T_VAC[#Headers])),
IF(IFERROR(MATCH(DATE(YEAR($C15),MONTH($C15),D$14),L_HOLS,0),0)>0,"HOL",
IF(@INDEX(L_WKNDS,WEEKDAY(DATE(YEAR($C15),MONTH($C15),D$14))),"WKND",
"Work"))))))


I am trying to add 1 line into the formula to return a value if there is more than one data entry in the vacation table but every time I do it gives me the error of "You've entered too many arguments for this function"
The formula below is what I am trying to enter, I cant see where my parenthesis are wrong
=IF(D$14>EOMONTH($C15,0)-$C15+1,"NA",
IF(OR(DATE(YEAR($C15),MONTH($C15),D$14)<I_ER_START, DATE(YEAR($C15),MONTH($C15),D$14)>I_ER_END),"NA",
IF(OR(DATE(YEAR($C15),MONTH($C15),D$14)<C_EMP_START, DATE(YEAR($C15),MONTH($C15),D$14)>C_EMP_END),"NE",
IFERROR(@IF(COUNTIFS(T_VAC[Employee],$C11,T_VAC[Start Date],D$10)>1,"1>",
@INDEX(T_VAC[Vacation Type],SUMPRODUCT(--(T_VAC[Employee]=I_ER_EMP),--(T_VAC[Start Date]=DATE(YEAR($C15),MONTH($C15),D$14)),ROW(T_VAC[Vacation Type]))-@ROW(T_VAC[#Headers])),
IF(IFERROR(MATCH(DATE(YEAR($C15),MONTH($C15),D$14),L_HOLS,0),0)>0,"HOL",
IF(@INDEX(L_WKNDS,WEEKDAY(DATE(YEAR($C15),MONTH($C15),D$14))),"WKND",
"Work"))))))


I attached are pictures of my workbook with sample data to help if needed
What I am looking for is that both the Team Dashboard (shows just 1 month) and Annual Employee Report (shows entire year) to match for the correct month, as of right now if I have more than one data entry for a day it will highlight blue in the Team Dashboard shown on January 6th, but in the Annual it shows up as a work day due to the iferror formal thats entered. Any help will be greatly appreciated!

 

[jasonb75]

That is a big mess to try and unravel, as far as I can see you have missed the closing parenthesis on the IF function that you added to the formula.

It think that I've added it in the correct place here, but as it contains table names I've not been able to confirm that in excel.

=IF(D$14>EOMONTH($C15,0)-$C15+1,"NA",
IF(OR(DATE(YEAR($C15),MONTH($C15),D$14)<I_ER_START, DATE(YEAR($C15),MONTH($C15),D$14)>I_ER_END),"NA",
IF(OR(DATE(YEAR($C15),MONTH($C15),D$14)<C_EMP_START, DATE(YEAR($C15),MONTH($C15),D$14)>C_EMP_END),"NE",
IFERROR(@IF(COUNTIFS(T_VAC[Employee],$C11,T_VAC[Start Date],D$10)>1,"1>",
@INDEX(T_VAC[Vacation Type],SUMPRODUCT(--(T_VAC[Employee]=I_ER_EMP),--(T_VAC[Start Date]=DATE(YEAR($C15),MONTH($C15),D$14)),ROW(T_VAC[Vacation Type]))-@ROW(T_VAC[#Headers]))),
IF(IFERROR(MATCH(DATE(YEAR($C15),MONTH($C15),D$14),L_HOLS,0),0)>0,"HOL",
IF(@INDEX(L_WKNDS,WEEKDAY(DATE(YEAR($C15),MONTH($C15),D$14))),"WKND",
"Work"))))))