XY Scatter plot labelling

[keelip01]

I have 3 columns consisting of; a label (an area name), an X value and a Y value. There are 365 rows.

The X and Y values have been charted in an XY Scatter Plot.

If I click on an individual data point in the chart, a text box appears with a label like: Series 1, 29.5, 37.6.

Is it possible, using VBA if necessary, to be able to display the label in some way (the area name, from the first column) for the selected data point?

 

[Andrew Poulsom]

Try this:

' --------------------------------
' Class module named Class1
' --------------------------------

Public WithEvents Ch As Chart

Dim IDNum As Long
Dim a As Long
Dim b As Long

Private Sub Ch_MouseDown(ByVal Button As Long, ByVal Shift As Long, ByVal x As Long, ByVal y As Long)
    Dim Rng As Range
'   *** Range containing labels - change to suit ***
    Set Rng = Worksheets("Sheet1").Range("A2:A5")
    Ch.GetChartElement x, y, IDNum, a, b
    If IDNum = xlSeries Then
        With ActiveChart.SeriesCollection(a).Points(b)
            .HasDataLabel = True
            With .DataLabel
                .Text = Rng.Cells(b, 1).Value
                .Position = xlLabelPositionAbove
            End With
        End With
    End If
End Sub

Private Sub Ch_MouseUp(ByVal Button As Long, ByVal Shift As Long, ByVal x As Long, ByVal y As Long)
    Ch.GetChartElement x, y, IDNum, a, b
    If IDNum = xlSeries Then
        With ActiveChart.SeriesCollection(a).Points(b)
            .HasDataLabel = False
        End With
    End If
End Sub

' ---------------
' Sheet module
' ---------------

Dim MyChart As New Class1

Private Sub Worksheet_Activate()
'   *** Change ChartObjects index to suit ***
    Set MyChart.Ch = ActiveSheet.ChartObjects(1).Chart
End Sub

 

[keelip01]

Many thanks for this. I will give it a try.