Xlookup/Index Match With Multiple Criteria

[acool]

Hi Everyone,

I am try to create a formula in Cells H2:H5, that will search values in cell D2:D5 and match them up against values in the lookup table in column F to return the corresponding value. I would first like to remove leading zeros from the comma delimited values in Column D. I would then like to search the comma delimited values in column D against Column F and then provided that corresponding value in Column H if it exists in the table. Any help would be greatly appreciated. I have attached a photo below for reference. Thank You!

 

[hagia_sofia]

Try this:

=--(MAP(D2:D5,F2:F5,LAMBDA(a,b,IF(ISNUMBER(SEARCH(b,a))=TRUE,MID(a,SEARCH(b,a),LEN(b))))))

 

[acool]

@hagia_sofia This works! However, if you don't mind me asking, what changes would need to be made to the formula if there table arrays were different range sizes? For example, if Column F was longer than Column D Range?

 

[acool]

@hagia_sofia This works! However, if you don't mind me asking, what changes would need to be made to the formula if there table arrays were different range sizes? For example, if Column F was longer than Column D Range?

In many scenarios, my lookup table will be either longer or shorter than the values column.

 

[hagia_sofia]

How about this then:

=LET(values,--(TRANSPOSE(TEXTSPLIT(TEXTJOIN(", ",,D2:D5),", "))),XLOOKUP(F2:F5,values,values))

 

[acool]

How about this then:

=LET(values,--(TRANSPOSE(TEXTSPLIT(TEXTJOIN(", ",,D2:D5),", "))),XLOOKUP(F2:F5,values,values))

@hagia_sofia Apologies, ***Values in Column D will be longer than the Lookup Values in Column G So if one of the values in Column D corresponds to G, return that value in Column E. As of now, it is only populating to row 9. Apologies for the confusion, and thank you for all of your help up until this point!

 

[hagia_sofia]

I still do not know whether I understand it correctly but let us give it a shot:

=LET(lookup,G2:G9,BYROW(D2:D16,LAMBDA(a,TEXTJOIN(", ",,XLOOKUP(--(TEXTSPLIT(TEXTJOIN(", ",,a);", ")),lookup,lookup,"")))))

 

[acool]

@hagia_sofia I am currently receiving this error message.

 

[hagia_sofia]

I see that I forgot to replace one semicolon with comma (I am not using English Excel) - here it is adjusted:

=LET(lookup,G2:G9,BYROW(D2:D16,LAMBDA(a,TEXTJOIN(", ",,XLOOKUP(--(TEXTSPLIT(TEXTJOIN(", ",,a),", ")),lookup,lookup,"")))))

 

[acool]

I see that I forgot to replace one semicolon with comma (I am not using English Excel) - here it is adjusted:

=LET(lookup,G2:G9,BYROW(D2:D16,LAMBDA(a,TEXTJOIN(", ",,XLOOKUP(--(TEXTSPLIT(TEXTJOIN(", ",,a),", ")),lookup,lookup,"")))))

This worked! You're the best-thank you!