WS looping

[urchino]

Dear Experts

I search through the forum and tried to improvise but it seems it is not working.
Wish to repeat a macro through different sheet name but the looping only on the first sheet.

Sub Test()
Dim Sh As Worksheet
    For Each Sh In ActiveWorkbook.Worksheets
        If Sh.Name <> "Inp*" Then
            With Sh
                    Dim c As Range
                        For Each c In Range("1:1").Cells
                            If c.Value = "Lock" Then
                            c.EntireColumn.Select
                    Selection.Locked = True
        End If
    Next c
            End With
        End If
    Next Sh
End Sub

Any help would be great. Thank you. Appreciate it.

 

[hrayani]

pls see if below helps

Sub Test()
    Dim Sh As Worksheet
    For Each Sh In ActiveWorkbook.Worksheets
        If Left(Sh.Name, 3) <> "Inp" Then ' Check if the sheet name doesn't start with "Inp"
            Dim c As Range
            For Each c In Sh.Range("1:1").Cells ' Specify the range for the current worksheet
                If c.Value = "Lock" Then
                    c.EntireColumn.Locked = True
                End If
            Next c
        End If
    Next Sh
End Sub

 

[urchino]

pls see if below helps

Sub Test()
    Dim Sh As Worksheet
    For Each Sh In ActiveWorkbook.Worksheets
        If Left(Sh.Name, 3) <> "Inp" Then ' Check if the sheet name doesn't start with "Inp"
            Dim c As Range
            For Each c In Sh.Range("1:1").Cells ' Specify the range for the current worksheet
                If c.Value = "Lock" Then
                    c.EntireColumn.Locked = True
                End If
            Next c
        End If
    Next Sh
End Sub

Works perfectly. Thank you.

 

[hrayani]

Works perfectly. Thank you.

you are welcome & thanks for the feedback