Worksheet_Change (adding two target addresses into one VBA code

[VonFeed]

Hello, I am trying to have a Worksheet_Change that will run a VBA code. Right now I have the first part done. What this code does is that it works with a Drop-down list in Cell V6 and when someone selects this drop-down list it will run a code called Do_it_1 and also change a commandbutton caption. This works great so far.

What I would like to do is, make this same code work for cell $V$2, which is also a drop-down list. When I tried to have them two separate items I would get a compile error: Ambiguous name detected:worksheet_change.

Here is my code:

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Count > 1 Then Exit Sub
If Target.Address <> "$V$6" Then Exit Sub
Application.Run "Do_it_1"
Select Case CommandButton1.Caption
Case "Hide Object Detail"
CommandButton1.Caption = "Expand Objects"
End Select
End Sub


Is there a way to add my second target address into my code? Also, I have not thought of this yet, will this only effect the active worksheet and not other worksheets in the same workbook? I would rather keep this to the active sheet only. Thank you for your help.

 

[mumps]

Try:

Private Sub Worksheet_Change(ByVal Target As Range)
    If Intersect(Target, Range("V2,V6")) Is Nothing Then Exit Sub
    If Target.Count > 1 Then Exit Sub
    Application.Run "Do_it_1"
    Select Case CommandButton1.Caption
        Case "Hide Object Detail"
            CommandButton1.Caption = "Expand Objects"
    End Select
End Sub

 

[Joe4]

You cannot have two "Worksheet_Change" event procedures on the same sheet.
For that matter, you cannot have two procedures with the same name in the same module.

EDIT: I slightly misread your original question. The code below shows how to structure if you did NOT want to do the exact same thing for both ranges.

You just need to have multiple code blocks in the one procedure, like this:

Private Sub Worksheet_Change(ByVal Target As Range)


    If Target.Count > 1 Then Exit Sub

'   Block1    
    If Target.Address = "$V$6" Then
        Application.Run "Do_it_1"
        Select Case CommandButton1.Caption
            Case "Hide Object Detail"
            CommandButton1.Caption = "Expand Objects"
        End Select
    End If
    
'   Block2
    If Target.Address = "$V$2" Then
        'DO STUFF HERE
    End If


End Sub

 

[VonFeed]

Wow, that was quick. It works perfectly. The first fix is what I needed, but seeing the second one might help me in any future endeavors. Thank you for your help.