Worksheet variable from array in ActiveChart source data

[SBF23456]

Greetings,

I am running into an error in defining the source data in the active chart on the line:

ActiveChart.SetSourceData Source:=Range( _
        "A(element)!$A:$A,A(element)!$E:$E,A(element)!$W:$W")

How am I able to define the value currently "A(element)" as the worksheet name in such a way that for each worksheet I am able to produce a chart?
If I can further clarify the question please let me know.

A = Array("AAL", "F", "X")

For element = LBound(A) To UBound(A)

    ActiveWorkbook.Worksheets(A(element)).Activate
    ActiveWorkbook.ActiveSheet.Range("A:A,E:E,W:W").Select
    ActiveSheet.Shapes.AddChart2(227, xlLine).Select
    ActiveChart.SetSourceData Source:=Range( _
        "A(element)!$A:$A,A(element)!$E:$E,A(element)!$W:$W")

 

[GWteB]

Hi & Welcome to MrExcel!

Give this a try and see whether it helps.

Sub SBF23456()

    Dim A As Variant, Element As Long, NewChart As Shape
    
    A = Array("AAL", "F", "X")
    For Element = LBound(A) To UBound(A)
        With ThisWorkbook.Worksheets(A(Element))
            Set NewChart = .Shapes.AddChart2(227, xlLine)
            NewChart.Chart.SetSourceData Source:=Range(A(Element) & "!$A:$A," & A(Element) & "!$E:$E," & A(Element) & "!$W:$W")
        End With
    Next
End Sub

 

[KOKOSEK]

If I understand correctly you want create chart on each of these sheets with data from these sheets.
In this code, at the moment of adding chart, you are already on sheet A(element) so you do not have to refer this way.
this should work:

A = Array("AAL", "F", "X")
For element = LBound(A) To UBound(A)
    ActiveWorkbook.Worksheets(A(element)).Activate
    ActiveWorkbook.ActiveSheet.Range("A:A,E:E,W:W").Select
    ActiveSheet.Shapes.AddChart2(227, xlLine).Select
    ActiveChart.SetSourceData Source:=ActiveSheet.Range("$A:$A,$E:$E,$W:$W")
Next element

 

[SBF23456]

Great, the charts appear to be working... Thanks!

 

[GWteB]

Using @KOKOSEK's way of referencing, however without activating or selecting anything, my final submission would look like:

Sub SBF23456()

    Dim A As Variant, Element As Long, NewChart As Shape
    
    A = Array("AAL", "F", "X")
    For Element = LBound(A) To UBound(A)
        With ThisWorkbook.Worksheets(A(Element))
            .Shapes.AddChart2(227, xlLine).Chart.SetSourceData Source:=.Range("$A:$A,$E:$E,$W:$W")
        End With
    Next
End Sub