Worksheet Deactivate Question

[gheyman]

I want to run a check before the user leaves the tab.

Private Sub Worksheet_Deactivate()
'
    Range("D1").Select
    ActiveCell.FormulaR1C1 = "=SUMIF(C[1],""parent"",C[9])"
    Range("D1").Select
'
    If Application.Range("D1") > 0 Then MsgBox "You or Someone has entered estimated hours/dollars against a PARENT WBS Task.  Parent level WBS Tasks are Sumary level items.  There should never be estimate directly bid to a Parent."
'
    Range("D1").Clear
'
End Sub

I want it to run when the user leaves the tab, but I am assuming "Deactivate" isn't what I think it is because its not working when I leave the tab. The code works if I run it. Is there a way to run this when they leave the tab?

 

[mikerickson]

Two things.
First, when the Deactivate event runs, the sheet it refers to is not the Active Sheet, so you'll have to qualtify all the cell references with Me.
Similarly, don't select in the deactivate event.

Private Sub Worksheet_Deactivate()

    With Me
        .Range("D1").FormulaR1C1 = "=SUMIF(C[1],""parent"",C[9])"
  
         If .Range("D1") > 0 Then MsgBox "You or Someone has entered estimated hours/dollars against a PARENT WBS Task.  Parent level WBS Tasks are Sumary level items.  There should never be estimate directly bid to a Parent."

        .Range("D1").Clear
    End With
End Sub

 

[Joe4]

How is it not working?

What value does your SUMIF return before you clear it?

Note, that you do not need those Select statements.
You can combine all this:

    Range("D1").Select
    ActiveCell.FormulaR1C1 = "=SUMIF(C[1],""parent"",C[9])"
    Range("D1").Select

into this:

    Range("D1").FormulaR1C1 = "=SUMIF(C[1],""parent"",C[9])"

 

[gheyman]

Thank You, Mike. Is there a way to go back to the sheet? I want to prevent them from leaving the tab if the condition is true Sheets("BOE")

 

[Joe4]

Thank You, Mike. Is there a way to go back to the sheet? I want to prevent them from leaving the tab if the condition is true Sheets("BOE")

Just put a statement in the TRUE portion of your IF statement that selects/activates that sheet again.

 

[mikerickson]

Private Sub Worksheet_Deactivate()

    With Me
        .Range("D1").FormulaR1C1 = "=SUMIF(C[1],""parent"",C[9])"
  
         If .Range("D1") > 0 Then
             .Activate
             MsgBox "You or Someone has entered estimated hours/dollars against a PARENT WBS Task.  Parent level WBS Tasks are Sumary level items.  There should never be estimate directly bid to a Parent."
        End If
        .Range("D1").Clear
    End With
End Sub

 

[steve the fish]

I came up with this and it seems to understand that the evaluation needs to be done on the deactivated sheet:

If Evaluate("=SUMIF(E:E,""parent"",M:M)") > 0 Then
    MsgBox "You or Someone has entered estimated hours/dollars against a PARENT WBS Task.  Parent level WBS Tasks are Sumary level items.  There should never be estimate directly bid to a Parent."
    Me.Select
End If

 

[gheyman]

Thanks everyone. I really appreciate all the options.