Working days auto updating based on start of month

[Tam12]

Hello,

i would like to add a formula to the attached that allows the working dates of the month to auto update once i change the full month in bold at the top.

i would like to do this for all days of the month, only working days.

hope this makes sense,

thanks

 

[etaf]

how about
in 1st cell put
=IF(WEEKDAY(Sheet1!B1,2)<6,Sheet1!B1,WORKDAY(Sheet1!B1,1))
then in 2nd cell put
=IF(A2="","",IF(MONTH(WORKDAY(A2,1))<>MONTH(A2),"",WORKDAY(A2,1)))

probably a single formula can be setup in 365 version

Book3
	A	B
1		6/1/24
2	6/3/24
3	6/4/24
4	6/5/24
5	6/6/24
6	6/7/24
7	6/10/24
8	6/11/24
9	6/12/24
10	6/13/24
11	6/14/24
12	6/17/24
13	6/18/24
14	6/19/24
15	6/20/24
16	6/21/24
17	6/24/24
18	6/25/24
19	6/26/24
20	6/27/24
21	6/28/24
22
23
24
25
26
27
28
Sheet1

Cell Formulas
Range	Formula
A2	A2	=IF(WEEKDAY(Sheet1!B1,2)<6,Sheet1!B1,WORKDAY(Sheet1!B1,1))
A3:A28	A3	=IF(A2="","",IF(MONTH(WORKDAY(A2,1))<>MONTH(A2),"",WORKDAY(A2,1)))

 

[Rick Rothstein]

I believe this should work starting from any date within the month...

=LET(s,SEQUENCE(DAY(EOMONTH(B1,0)),,B1),u,UNIQUE(WORKDAY(s,1)),FILTER(u,MONTH(u)=MONTH(B1)))

 

[Dave Patton]

Do you want to ignore holidays?

Dates Time.xlsb
	A	B
1		Sat 1-06-24
2	Mon 3-06-24
3	Tue 4-06-24
4	Wed 5-06-24
5	Thu 6-06-24
6	Fri 7-06-24
7	Mon 10-06-24
8	Tue 11-06-24
9	Wed 12-06-24
10	Thu 13-06-24
11	Fri 14-06-24
12	Mon 17-06-24
13	Tue 18-06-24
14	Wed 19-06-24
15	Thu 20-06-24
16	Fri 21-06-24
17	Mon 24-06-24
18	Tue 25-06-24
19	Wed 26-06-24
20	Thu 27-06-24
21	Fri 28-06-24
5f

Cell Formulas
Range	Formula
A2:A21	A2	=WORKDAY(B1-1,SEQUENCE(NETWORKDAYS(B1,EOMONTH(B1,0))))
Dynamic array formulas.