WORKDAY Function excluding Fridays

[salahmost]

I have searched for a Function excluding Fridays and found one by barry houdini for excluding Sundays :
If I have a date in A1 and want to add the number of workdays in B1, counting all days except Fridays as workdays:

=A1-WEEKDAY(A1,3)+INT(7/6*(B1+MIN(5,WEEKDAY(A1,3))))

format as date...How to replace sundays with Fridays?
Thanks in advanced.


-----------------------
Salah

 

[barry houdini]

To exclude Fridays change to this formula

=A1-WEEKDAY(A1+2,3)+INT(7/6*(B1+MIN(5,WEEKDAY(A1+2,3))))

 

[salahmost]

Perfect Barry ...It works as I needed.
Thank you ...

Is there a way to amend holidays to that Formula ?

Thank you so much for your help.

 

[salahmost]

If I have a period from 01/01/2008 and add 15 days to it, The result must be 17 /01 /2008 (dd-mm-yyyy) ... As 04/01/2008 and 11/01/2008 are Fridays. but the formula result is 19/01/2008 ....How to modify this the formula?

 

[barry houdini]

If start date is 1/1/2008 and you add 15 days then I believe the answer would be 19/1/2008. It's only 17/1/2008 if you assume that day 1 is the start date, i.e. if you add 1 day to 1/1/2008 you get 1/1/2008 [Workday doesn't work like that, it assumes that day 1 is the first workday after the start date].

If you want it to work that way, though, you can change formula to

=A1-1-WEEKDAY(A1+1,3)+INT(7/6*(B1+MIN(5,WEEKDAY(A1+1,3))))

If you want to exclude holidays too then you need a different approach entirely. This formula will exclude holidays (listed in H1:H10) and also count the start date as day 1

=SMALL(IF(WEEKDAY(A1+ROW(INDIRECT("1:"&B1*10))-1)<>6,IF(ISNA(MATCH(A1+ROW(INDIRECT("1:"&B1*10))-1,H$1:H$10,0)),ROW(INDIRECT("1:"&B1*10)))),B1)+A1-1

Formula needs to be confirmed with CTRL+SHIFT+ENTER

 

[salahmost]

Great Barry .
I appreciate so much your help.

Thank you.

-----------------------
Salah