word to pdf

[jillibillijames]

Hi,

I have around 50 word documents in and i want to convert all of them to pdf formate. can some one tell me the code for it.

 

[Macropod]

What version of Word are you using? If it's Word 2007 & later, you can save in PDF format; otherwise, you'll need a 3rd-party PDF converter.

 

[jillibillijames]

Thanks for your help.

But I have around 50 files do i need to open all the files and save it in pdf.

 

[Macropod]

It's impossible to convert the files without opening them. You could automate the process with a macro. As you still haven't said what version of Word you're using, there's not much more I can add.

 

[jillibillijames]

I'm using word-2007.

Thank you very much for your response

 

[Macropod]

Try the following macro. Simply point it to the target folder and PDFs will be made of all document in that folder.

Sub SaveDocuments2PDF()
Application.ScreenUpdating = False
Dim strFolder As String, strFile As String, wdDoc As Document
strFolder = GetFolder
If strFolder = "" Then Exit Sub
strFile = Dir(strFolder & "\*.doc", vbNormal)
While strFile <> ""
  Set wdDoc = Documents.Open(FileName:=strFolder & "\" & strFile, AddToRecentFiles:=False, Visible:=False)
  wdDoc.SaveAs2 FileName:=strFolder & "\" & Split(wdDoc.Name, ",")(0), Fileformat:=wdFormatPDF, AddToRecentFiles:=False
  wdDoc.Close SaveChanges:=False
  strFile = Dir()
Wend
Set wdDoc = Nothing
Application.ScreenUpdating = True
End Sub

Function GetFolder() As String
Dim oFolder As Object
GetFolder = ""
Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
Set oFolder = Nothing
End Function

For instructions on installing & running macros, see: http://www.gmayor.com/installing_macro.htm