Why won't my code run on each worksheet?

[Dr_Beanie]

I am trying to get this code to loop through each worksheet...but it doesn't seem to want to!

Sub BorderUsedCells()

For Each ws In Worksheets


    For Each rngCell In Range("A5:E25")
    If rngCell.Value > "" Then
        r = rngCell.Row
        c = rngCell.Column
        Range(Cells(r, c), Cells(r, c)).Select
            With Selection.Borders
                .LineStyle = xlContinuous
                .Weight = xlThin
                .ColorIndex = xlAutomatic
            End With
            End If
            Next
            
Next ws
End Sub

Thanks for your help

 

[footoo]

Each ws needs to be referenced within the code.
Also, Select can only be used on the active worksheet (otherwise run-time error 1004 will occur) :

Sub BorderUsedCells()
For Each ws In Worksheets
    For Each rngCell In ws.Range("A5:E25")
        If rngCell.Value > "" Then
            With rngCell.Borders
                .LineStyle = xlContinuous
                .Weight = xlThin
                .ColorIndex = xlAutomatic
            End With
        End If
    Next
Next ws
End Sub

This code is more efficient (no cell loop) :

Sub BorderUsedCells()
Dim rng As Range
On Error Resume Next
For Each ws In Worksheets
    Set rng = Union(ws.[A5:E25].SpecialCells(xlCellTypeFormulas, 23), _
        ws.[A5:E25].SpecialCells(xlCellTypeConstants, 23))
    With rng.Borders
        .LineStyle = xlContinuous
        .Weight = xlThin
        .ColorIndex = xlAutomatic
    End With
Next
On Error GoTo 0
End Sub

 

[footoo]

Correction :

Sub BorderUsedCells()
Dim ws As Worksheet, rng As Range
On Error Resume Next
For Each ws In Worksheets
    Set rng = ws.[A5:E25]
    With rng.Borders
        .LineStyle = xlContinuous
        .Weight = xlThin
        .ColorIndex = xlAutomatic
    End With
    On Error Resume Next
    rng.SpecialCells(xlCellTypeBlanks) _
        .Borders.LineStyle = xlNone
    With Application
        .ReplaceFormat.Clear
        .ReplaceFormat.Borders.LineStyle = xlNone
        rng.SpecialCells(xlCellTypeFormulas, 23). _
            Replace """", "", SearchFormat:=False, _
            ReplaceFormat:=True
        .ReplaceFormat.Clear
    End With
Next
On Error GoTo 0
End Sub