What and where put code to run macro in all sheets (in opened workbook)

[Vladj]

My problem is, where and what to put inside my macro to run macro in all sheets in currently opened workbook. I tried several things but without success.

[COLOR=#333333]
Sub LoopAllExcelFilesInFolder()

Dim wb As Workbook
Dim myPath As String
Dim myFile As String
Dim myExtension As String
Dim FldrPicker As FileDialog

'Optimize Macro Speed
  Application.ScreenUpdating = False
  Application.EnableEvents = False
  Application.Calculation = xlCalculationManual

'Retrieve Target Folder Path From User
  Set FldrPicker = Application.FileDialog(msoFileDialogFolderPicker)

    With FldrPicker
      .Title = "Select A Target Folder"
      .AllowMultiSelect = False
        If .Show <> -1 Then GoTo NextCode
        myPath = .SelectedItems(1) & ""
    End With

'In Case of Cancel
NextCode:
  myPath = myPath
  If myPath = "" Then GoTo ResetSettings

'Target File Extension (must include wildcard "*")
  myExtension = "*.xls*"

'Target Path with Ending Extention
  myFile = Dir(myPath & myExtension)

'Loop through each Excel file in folder
  Do While myFile <> ""
    'Set variable equal to opened workbook
      Set wb = Workbooks.Open(Filename:=myPath & myFile)
    
    'Ensure Workbook has opened before moving on to next line of code
      DoEvents
    
    Range("J33").Formula = "=FIXED(SUM(L33:T33),2)"
    Range("J33", "J" & Cells(Rows.Count, 1).End(xlUp).Row).FillDown
         
    'Save and Close Workbook
      wb.Close SaveChanges:=True
      
    'Ensure Workbook has closed before moving on to next line of code
      DoEvents

    'Get next file name
      myFile = Dir
  Loop

'Message Box when tasks are completed
  MsgBox "Riješeno!!!"

ResetSettings:
  'Reset Macro Optimization Settings
    Application.EnableEvents = True
    Application.Calculation = xlCalculationAutomatic
    Application.ScreenUpdating = True

End Sub[/COLOR]

Thanks in advance.

 

[gsbelbin]

If I understand you correctly you could try this

Declare a variable, say, sht as Worksheet.

Then where you have

Range("J33").Formula = "=FIXED(SUM(L33:T33),2)"
Range("J33", "J" & Cells(Rows.Count, 1).End(xlUp).Row).FillDown

Change this to

For Each sht in Worksheets
sht.Range("J33").Formula = "=FIXED(SUM(L33:T33),2)"
sht.Range("J33", "J" & Cells(Rows.Count, 1).End(xlUp).Row).FillDown
Next sht

 

[Vladj]

OMG... I tried few combinations like yours and it was unsuccessful. I can't believe that now working everything fine.
Probably I miss some letter...
Anyway, thank you very much.