VLookup Not Returning Valid Value for All Items

[psycoperl]

I am working on a worksheet that has a Data Validation dropdown list that allows for Human Readable Funding Sources to be selected. Then using a VLookup to get the internal code for use in file naming conventions.

For each of the values in the FundingSource tab Column A. It is supposed to display the value of Column B in Column N of UpdateTimeSheets.
The only item that it does not work for is "B Student Employment" which for all the rows that use that value it returns #N/A instead of "BSEP" which is the code in the FundingSource sheet.

How can I get the B Student Employment to work?

_PREP_CleanUpFiles.xlsx
	G	H	I			L	M	N
32	B Student Employment	1/26/2017	2/8/2017			FY 2017	FY 2017	#N/A
33	College Assistant	11/17/2016	11/30/2016			FY 2017	FY 2017	CA
34	Other Tax Levy	12/1/2016	12/14/2016			FY 2017	FY 2017	NYS
35	Federal Work Study	12/15/2016	12/28/2016			FY 2017	FY 2017	FWS
UpdateTimeSheets

Cell Formulas
Range	Formula
L32:L35	L32	=IF(LEN(TRIM($A32))>0,(IF(AND(NOT(ISBLANK(H32)),NOT(ISBLANK(I32))),IF(J32=K32,CONCAT("FY ",J32),"#$MixedPeriod$#"),IF(AND(LEN($C32)>3,OR(ISBLANK($H32)),ISBLANK($I32)),"#",""))),"")
M32:M35	M32	=IF(LEN(TRIM($A32))>0,L32,"")
N32:N35	N32	=VLOOKUP($G32,FundingSource!A:B,2)

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
M3:M14992	Expression	=$M3="#$MixedPeriod$#"	text	NO
M3:M14992	Expression	=AND(LEN(TRIM($M3))<5,LEN(TRIM($C3))>=4)	text	NO

Cells with Data Validation
Cell	Allow	Criteria
M32:M35	List	=TimeSheetFYFolderList!$A$1:$A$24

_PREP_CleanUpFiles.xlsx
	A	B
1
2	College Assistant	CA
3	Federal Work Study	FWS
4	Other Tax Levy	NYS
5	B Student Employment	BSEP
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
FundingSource

 

[Fluff]

You need to specify the final argument in the vlookup like

=VLOOKUP($G32,FundingSource!A:B,2,0)

 

[psycoperl]

You need to specify the final argument in the vlookup like

=VLOOKUP($G32,FundingSource!A:B,2,0)

Thank you... just curious why only the B Student Employment value was not working while the College Assistant, Other Tax Levy and Federal Work Study values all worked as expected.

 

[Fluff]

Because you were doing an approximate the data must be sorted A-Z & all the other values are in alphabetical order.