VBA using IF OR THEN statements and returning the product of cells in two columns.

[ssmith3156]

I need to write a VBA code multiplies the cells in columns J & K to return a result in column L, if the value in the cell of column H is L or O. For example: Since H21=L, then L21=J21*K21. The columns will never change, but the rows will change every month. This is what I have written, but it is not working.

Sub LaborCost()
'
' LaborCost Macro
' Enters formula to calculate cost for L and OT cost types.
'

'
Sheets("TOTAL COSTS").Select
Dim LastRow As Long
Dim i As Long
LastRow = Range("H" & Rows.Count).End(xlUp).Row

For i = 2 To LastRow
If Range("H" & i).Value = L Or Range("H" & i).Value = O Then
Range("L" & i).Value = PRODUCT("J" & i:"K" & i)

End If
Next i
Range("A2").Select
End Sub

 

[DanteAmor]

Hi @ssmith3156. Welcome to the MrExcel forum. Please accept my warmest greetings and sincere hope that all is well.


Try this:

Sub LaborCost()
  ' LaborCost Macro
  ' Enters formula to calculate cost for L and OT cost types.
 
  Dim i As Long
  Sheets("TOTAL COSTS").Select
  For i = 2 To Range("H" & Rows.Count).End(xlUp).Row
    If Range("H" & i).Value = "L" Or Range("H" & i).Value = "O" Then
      Range("L" & i).Value = Range("J" & i).Value * Range("K" & i).Value
    End If
  Next i
End Sub

--------------
Or this:

Sub LaborCost_2()
  Sheets("TOTAL COSTS").Select
  With Range("L2:L" & Range("H" & Rows.Count).End(xlUp).Row)
    .Formula = "=IF(OR(H2=""L"",H2=""O""),J2*K2,"""")"
    .Value = .Value
  End With
End Sub

-------------------------------

Let me know the result and I'll get back to you as soon as I can.
Sincerely
Dante Amor
--------------

 

[ssmith3156]

@DanteAmor, the first one worked beautifully! Thank you so much for your help!