VBA user form search code

[FGaxha]

Hi Masters,
I have a vbs code for user form search:
Ia pooling data only for January, and I need to pull data for February, march, April. Please help?

Private Sub TextBox1_Change()
Dim i As Long
Me.TextBox1 = Format(StrConv(Me.TextBox1, vbLowerCase))
Me.ListBox1.Clear
Me.ListBox1.AddItem "OEM Name"
Me.ListBox1.List(0, 1) = "Platform"
Me.ListBox1.List(0, 2) = "Jan"
Me.ListBox1.List(0, 3) = "Feb"
Me.ListBox1.List(0, 4) = "Mar"
Me.ListBox1.Selected(0) = True
For i = 2 To Sheet1.Range("A1000000").End(xlUp).Row
For X = 1 To Len(Sheet1.Cells(i, 1))
a = Me.TextBox1.TextLength
If LCase(Mid(Sheet1.Cells(i, 1), X, a)) = Me.TextBox1 And Me.TextBox1 <> "" Then
Me.ListBox1.AddItem Sheet1.Cells(i, 1)
Me.ListBox1.List(ListBox1.ListCount - 1, 1) = "" & Sheet1.Cells(i, 2)
Me.ListBox1.List(ListBox1.ListCount - 1, 2) = "" & Sheet1.Cells(i, 3)
End If
Next X
Next i
End Sub

Private Sub UserForm_Click()

End Sub

 

[DanteAmor]

Try this:

Private Sub TextBox1_Change()
  Dim i As Long, j As Long
  
  Me.TextBox1 = Format(StrConv(Me.TextBox1, vbLowerCase))
  With ListBox1
    .List = Sheet1.Range("A1:N1").Value
    .Clear
    .AddItem
    
    'I assume the headers are in row 1 of sheet1
    For j = 1 To 14
      .List(.ListCount - 1, j - 1) = "" & Sheet1.Cells(1, j)
    Next
    For i = 2 To Sheet1.Range("A1000000").End(xlUp).Row
      If LCase(Sheet1.Range("A" & i).Value) Like "*" & TextBox1.Text & "*" Then
        .AddItem
        For j = 1 To 14
          .List(.ListCount - 1, j - 1) = "" & Sheet1.Cells(i, j)
        Next j
      End If
    Next i
  End With
End Sub

Pull data up to column 14, I assume it is December, if you only need until April, then change the number 14 to a 6.


----- --
Let me know the result and I'll get back to you as soon as I can.
Sincerely
Dante Amor
----- --

 

[FGaxha]

Hi Dante,
Thanks for the reoly, it does not work, it is pulling data just for first three columns.
Yeas header is A1 to N

 

[DanteAmor]

You must change the ColumnCount property of the listbox to 14

 

[FGaxha]

You right, It works great after changing to 14,.
Thank you for your help