VBA used to copy DATA to unopened Workbook

[Ragarm13]

I have VBA code that copies data from one WB to another, but for some reason the .PasteSpecial xl:= PasteValues doesn't work. I paste the formulas and all.

Sub trial()

    Dim wb As Workbook
    Dim sheet As Worksheet
    Set sheet = ThisWorkbook.Sheets("FLEX")
    sheet.Activate
    ThisWorkbook.Worksheets("FLEX").Range("B5:K20").Select
    Selection.Copy
    
    Set wb = Workbooks.Open("C:\NewBook.xlsx")
    wb.Worksheets("Time").Activate
    
    lastRow = ActiveSheet.Cells(Rows.Count, 1).End(xlUp).Row
    ActiveSheet.Cells(lastRow + 1, 1).Select
    
    ActiveSheet.PasteSpecial xl = PasteValues
    ActiveWorkbook.Save
    
    'ActiveWorkbook.Close savechanges = True
    
    Set wb = Nothing
    
    ThisWorkbook.Worksheets("FLEX").Activate
    'ThisWorkbook.Worksheets("FLEX").Cells ("Time")
    
    Application.CutCopyMode = False
    

End Sub

I tried

ActiveSheet.PasteSpecial xl = PasteValues Paste:=PasteValues

But that didn't work either

 

[MARK858]

Maybe...

Sub trial()

    Dim wb As Workbook
    Dim mysheet As Worksheet, DestWS As Worksheet
    Dim lastRow As Long
  
    Set wb = Workbooks.Open("C:\NewBook.xlsx")
  
    Set mysheet = ThisWorkbook.Sheets("FLEX")
    Set DestWS = wb.Worksheets("Time")
  
    lastRow = DestWS.Cells(Rows.Count, 1).End(xlUp).Row
  
    With mysheet.Range("B5:K20")
        DestWS.Cells(lastRow + 1, 1).Resize(.Rows.Count, .Columns.Count).Value = .Value
    End With
  
    wb.Save
  

    Set wb = Nothing
  
    ThisWorkbook.Worksheets("FLEX").Activate
 
End Sub

Btw

 .PasteSpecial xl:= PasteValues

should be

.PasteSpecial Paste:=xlPasteValues

or just

.PasteSpecial xlValues

 

[Ragarm13]

Maybe...

Sub trial()

    Dim wb As Workbook
    Dim mysheet As Worksheet, DestWS As Worksheet
    Dim lastRow As Long
 
    Set wb = Workbooks.Open("C:\NewBook.xlsx")
 
    Set mysheet = ThisWorkbook.Sheets("FLEX")
    Set DestWS = wb.Worksheets("Time")
 
    lastRow = DestWS.Cells(Rows.Count, 1).End(xlUp).Row
 
    With mysheet.Range("B5:K20")
        DestWS.Cells(lastRow + 1, 1).Resize(.Rows.Count, .Columns.Count).Value = .Value
    End With
 
    wb.Save
 

    Set wb = Nothing
 
    ThisWorkbook.Worksheets("FLEX").Activate
 
End Sub

Btw

 .PasteSpecial xl:= PasteValues

should be

.PasteSpecial Paste:=xlPasteValues

or just

.PasteSpecial xlValues

That works! Thank you for the info!