VBA to select Dates Pivot Table

[DalPai]

I have a PivotTable with values filtered by dates. Dates range from 01/01/2018 to 12/31/2019.


But I need to select only dates until the value of E4 cell (eg.: 03/29/2019).


It is not difficult to do manually, but I wanted to try using a macro to speed things up.


Recording the beginning of the macro, I got this:

Sub teste()
'
' teste Macro
'


'
    ActiveSheet.PivotTables("Tabela dinâmica5").PivotFields("Data Arrumada"). _
        CurrentPage = "(All)"
    With ActiveSheet.PivotTables("Tabela dinâmica5").PivotFields("Data Arrumada")
        .PivotItems("4/27/2018").Visible = False
        .PivotItems("6/29/2018").Visible = False
        .PivotItems("7/13/2018").Visible = False
        .PivotItems("7/27/2018").Visible = False
    End With
End Sub

But I don't know much about VBA, so I'm kind of lost.


Any help?

Best Regards

 

[DanteAmor]

Try this

Sub Select_Dates()
    Dim pi As PivotItem
    Dim n As Long
    
    Application.ScreenUpdating = False
    n = 0
    With ActiveSheet.PivotTables("Tabela dinâmica5").PivotFields("Data Arrumada")
        .ClearAllFilters
        
        For Each pi In .PivotItems
            If CDate(pi) > Range("E4").Value Then
                n = n + 1
                If n < .PivotItems.Count Then
                    pi.Visible = False
                Else
                    MsgBox "No match"
                    .ClearAllFilters
                End If
            End If
        Next
    End With
End Sub